pkgs/games/left4gore/default.nix

   1 { stdenvNoCC, lib, fetchurl, buildFHSUserEnv }:
   2
   3 let
   4   version = "2.3";
   5
   6   # Unwrapped package, for putting into the FHS env
   7   left4gore-unwrapped = stdenvNoCC.mkDerivation {
   8     pname = "left4gore-unwrapped";
   9     inherit version;
  10
  11     src = fetchurl {
  12       url = "http://www.left4gore.com/dist/left4gore-${version}-linux.tar.gz";
  13       sha256 = "1n57nh32ybn6kirn8djh0nsjx6m84c0jfi1x8r4w2qr0qky3z7p0";
  14     };
  15
  16     installPhase = ''
  17       mkdir -p $out/bin
  18       cp left4gore $out/bin
  19     '';
  20   };
  21
  22   # FHS env, as patchelf will not work
  23   env = buildFHSUserEnv {
  24     name = "left4gore-env-${version}";
  25     targetPkgs = _: [ left4gore-unwrapped ];
  26     runScript = "left4gore";
  27   };
  28
  29 in stdenvNoCC.mkDerivation {
  30   pname = "left4gore";
  31   inherit version;
  32
  33   dontUnpack = true;
  34   dontConfigure = true;
  35   dontBuild = true;
  36
  37   installPhase = ''
  38     mkdir -p $out/bin
  39     ln -s ${env}/bin/* $out/bin/left4gore
  40   '';
  41
  42   meta = with lib; {
  43     homepage = "http://www.left4gore.com";
  44     description = "Memory patcher which adds the gore back into Left 4 Dead 2";
  45     license = licenses.unfree; # Probably the best choice
  46     maintainers = with maintainers; [ das_j ];
  47   };
  48 }