pkgs/games/openra/engine.nix

   1 /*  The package defintion for an OpenRA engine.
   2     It shares code with `mod.nix` by what is defined in `common.nix`.
   3     Similar to `mod.nix` it is a generic package definition,
   4     in order to make it easy to define multiple variants of the OpenRA engine.
   5     For each mod provided by the engine, a wrapper script is created,
   6     matching the naming convention used by `mod.nix`.
   7     This package could be seen as providing a set of in-tree mods,
   8     while the `mod.nix` pacakges provide a single out-of-tree mod.
   9 */
  10 { lib, stdenv
  11 , packageAttrs
  12 , patchEngine
  13 , wrapLaunchGame
  14 , engine
  15 }:
  16
  17 with lib;
  18
  19 stdenv.mkDerivation (recursiveUpdate packageAttrs rec {
  20   pname = "openra";
  21   version = "${engine.name}-${engine.version}";
  22
  23   src = engine.src;
  24
  25   postPatch = patchEngine "." version;
  26
  27   configurePhase = ''
  28     runHook preConfigure
  29
  30     make version VERSION=${escapeShellArg version}
  31
  32     runHook postConfigure
  33   '';
  34
  35   buildFlags = [ "DEBUG=false" "default" "man-page" ];
  36
  37   checkTarget = "nunit test";
  38
  39   installTargets = [
  40     "install"
  41     "install-linux-icons"
  42     "install-linux-desktop"
  43     "install-linux-appdata"
  44     "install-linux-mime"
  45     "install-man-page"
  46   ];
  47
  48   postInstall = ''
  49     ${wrapLaunchGame ""}
  50
  51     ${concatStrings (map (mod: ''
  52       makeWrapper $out/bin/openra $out/bin/openra-${mod} --add-flags Game.Mod=${mod}
  53     '') engine.mods)}
  54   '';
  55
  56   meta = {
  57     inherit (engine) description homepage;
  58   };
  59 })