pkgs/tools/admin/pulumi/default.nix

   1 { lib, stdenv, fetchurl, autoPatchelfHook, makeWrapper, installShellFiles }:
   2
   3 with lib;
   4
   5 let
   6   data = import ./data.nix {};
   7 in stdenv.mkDerivation {
   8   pname = "pulumi";
   9   version = data.version;
  10
  11   postUnpack = ''
  12     mv pulumi-* pulumi
  13   '';
  14
  15   srcs = map (x: fetchurl x) data.pulumiPkgs.${stdenv.hostPlatform.system};
  16
  17   installPhase = ''
  18     install -D -t $out/bin/ *
  19   '' + optionalString stdenv.isLinux ''
  20     wrapProgram $out/bin/pulumi --set LD_LIBRARY_PATH "${stdenv.cc.cc.lib}/lib"
  21   '' + ''
  22     installShellCompletion --cmd pulumi \
  23       --bash <($out/bin/pulumi completion bash) \
  24       --fish <($out/bin/pulumi completion fish) \
  25       --zsh  <($out/bin/pulumi completion zsh)
  26   '';
  27
  28   nativeBuildInputs = [ installShellFiles ] ++ optionals stdenv.isLinux [ autoPatchelfHook makeWrapper ];
  29
  30   meta = {
  31     homepage = "https://pulumi.io/";
  32     description = "Pulumi is a cloud development platform that makes creating cloud programs easy and productive";
  33     sourceProvenance = with sourceTypes; [ binaryNativeCode ];
  34     license = with licenses; [ asl20 ];
  35     platforms = builtins.attrNames data.pulumiPkgs;
  36     maintainers = with maintainers; [
  37       ghuntley
  38       peterromfeldhk
  39       jlesquembre
  40       cpcloud
  41     ];
  42   };
  43 }