pkgs/tools/cd-dvd/dvd+rw-tools/default.nix

   1 { lib, stdenv, fetchurl, fetchpatch, cdrtools, m4 }:
   2
   3 stdenv.mkDerivation rec {
   4   pname = "dvd+rw-tools";
   5   version = "7.1";
   6
   7   src = fetchurl {
   8     url = "http://fy.chalmers.se/~appro/linux/DVD+RW/tools/${pname}-${version}.tar.gz";
   9     sha256 = "1jkjvvnjcyxpql97xjjx0kwvy70kxpiznr2zpjy2hhci5s10zmpq";
  10   };
  11
  12   # Patches from Gentoo
  13   patches = [ ]
  14   ++ builtins.map ({pfile, sha256}: fetchpatch {
  15        url = "https://gitweb.gentoo.org/repo/gentoo.git/plain/app-cdr/dvd+rw-tools/files/${pfile}?id=b510df361241e8f16314b1f14642305f0111dac6";
  16        inherit sha256;
  17      })
  18      [{ pfile = "dvd+rw-tools-7.0-dvddl-r1.patch"; sha256 = "12l33jq6405shfwdycrj52qmd07h5bsp1vjaddknfri456azjny5"; }
  19       { pfile = "dvd+rw-tools-7.0-glibc2.6.90.patch"; sha256 = "1fb3gap2in782pa4164h1w0ha8ggsq3inissa1k0zn2p2r3rb5ln"; }
  20       { pfile = "dvd+rw-tools-7.0-reload.patch"; sha256 = "12v2y2y6ci5hh6lbmsk97dzgznrm4bxwhc81mq684ix0qspb9mq4"; }
  21       { pfile = "dvd+rw-tools-7.0-sysmacros.patch"; sha256 = "1rkb26cyhfxklkmna3l9b4797f6gzlxyqqin44jwnq3jmwfrs6v0"; }
  22       { pfile = "dvd+rw-tools-7.0-wctomb-r1.patch"; sha256 = "1xg770l0b4bjn30y7nqg619v4m5ickcn2n8hv9k2an6r191daq58"; }
  23       { pfile = "dvd+rw-tools-7.0-wexit.patch"; sha256 = "0sqzlkm19fmjx4lzxkxwn2ymrj9fq0zk0jkys3xm6xvd2ibb6kxl"; }
  24       { pfile = "dvd+rw-tools-7.1-bluray_pow_freespace.patch"; sha256 = "0iscz8fs5002ymk6wl2fz4x06b7bdnc57rfz8kbv3216acqi5rv3"; }
  25       { pfile = "dvd+rw-tools-7.1-bluray_srm+pow.patch"; sha256 = "0sy40m12w987i6g0cyxv8cfmab4vp7cd222lv05apknfi2y7smmw"; }
  26       { pfile = "dvd+rw-tools-7.1-lastshort.patch"; sha256 = "01wspv70sil20khkg5kj086b1x8rrig4yhcq9s88bdjd42nv0vpx"; }
  27       { pfile = "dvd+rw-tools-7.1-noevent.patch"; sha256 = "1kbmxpg15wci33f2h6pxxvf3qm0kpyzx9wj5a3l67sk34hvza3z6"; }
  28      ];
  29
  30   nativeBuildInputs = [ m4 ];
  31   buildInputs = [ cdrtools ];
  32
  33   makeFlags = [ "prefix=${placeholder "out"}" ];
  34
  35   meta = with lib; {
  36     homepage = "http://fy.chalmers.se/~appro/linux/DVD+RW/tools";
  37     description = "Tools for mastering Blu-ray and DVD+-RW/+-R media";
  38     platforms = platforms.linux;
  39     license = with licenses; [ gpl2 publicDomain ];
  40   };
  41 }