pkgs/tools/compression/lz4/default.nix

   1 { lib, stdenv, fetchFromGitHub, fetchpatch, valgrind
   2 , enableStatic ? stdenv.hostPlatform.isStatic
   3 , enableShared ? !stdenv.hostPlatform.isStatic
   4 }:
   5
   6 stdenv.mkDerivation rec {
   7   pname = "lz4";
   8   version = "1.9.4";
   9
  10   src = fetchFromGitHub {
  11     sha256 = "sha256-YiMCD3vvrG+oxBUghSrCmP2LAfAGZrEaKz0YoaQJhpI=";
  12     rev = "v${version}";
  13     repo = pname;
  14     owner = pname;
  15   };
  16
  17   patches = [
  18     (fetchpatch { # https://github.com/lz4/lz4/pull/1162
  19       name = "build-shared-no.patch";
  20       url = "https://github.com/lz4/lz4/commit/851ef4b23c7cbf4ceb2ba1099666a8b5ec4fa195.patch";
  21       sha256 = "sha256-P+/uz3m7EAmHgXF/1Vncc0uKKxNVq6HNIsElx0rGxpw=";
  22     })
  23   ];
  24
  25   # TODO(@Ericson2314): Separate binaries and libraries
  26   outputs = [ "bin" "out" "dev" ];
  27
  28   buildInputs = lib.optional doCheck valgrind;
  29
  30   enableParallelBuilding = true;
  31
  32   makeFlags = [
  33     "PREFIX=$(out)"
  34     "INCLUDEDIR=$(dev)/include"
  35     "BUILD_STATIC=${if enableStatic then "yes" else "no"}"
  36     "BUILD_SHARED=${if enableShared then "yes" else "no"}"
  37     "WINDRES:=${stdenv.cc.bintools.targetPrefix}windres"
  38   ]
  39     # TODO make full dictionary
  40     ++ lib.optional stdenv.hostPlatform.isMinGW "TARGET_OS=MINGW"
  41     ;
  42
  43   doCheck = false; # tests take a very long time
  44   checkTarget = "test";
  45
  46   # TODO(@Ericson2314): Make resusable setup hook for this issue on Windows.
  47   postInstall =
  48     lib.optionalString stdenv.hostPlatform.isWindows ''
  49       mv $out/bin/*.dll $out/lib
  50       ln -s $out/lib/*.dll
  51     ''
  52     + ''
  53       moveToOutput bin "$bin"
  54     '';
  55
  56   meta = with lib; {
  57     description = "Extremely fast compression algorithm";
  58     longDescription = ''
  59       Very fast lossless compression algorithm, providing compression speed
  60       at 400 MB/s per core, with near-linear scalability for multi-threaded
  61       applications. It also features an extremely fast decoder, with speed in
  62       multiple GB/s per core, typically reaching RAM speed limits on
  63       multi-core systems.
  64     '';
  65     homepage = "https://lz4.github.io/lz4/";
  66     license = with licenses; [ bsd2 gpl2Plus ];
  67     platforms = platforms.all;
  68   };
  69 }