pkgs/tools/filesystems/bcachefs-tools/default.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , pkg-config
   5 , docutils
   6 , libuuid
   7 , libscrypt
   8 , libsodium
   9 , keyutils
  10 , liburcu
  11 , zlib
  12 , libaio
  13 , zstd
  14 , lz4
  15 , python3Packages
  16 , udev
  17 , valgrind
  18 , nixosTests
  19 , fuse3
  20 , fuseSupport ? false
  21 }:
  22
  23 stdenv.mkDerivation {
  24   pname = "bcachefs-tools";
  25   version = "unstable-2022-09-28";
  26
  27   src = fetchFromGitHub {
  28     owner = "koverstreet";
  29     repo = "bcachefs-tools";
  30     rev = "99caca2c70f312c4a2504a7e7a9c92a91426d885";
  31     sha256 = "sha256-9bFTBFkQq8SvhYa9K4+MH2zvKZviNaq0sFWoeGgch7g=";
  32   };
  33
  34   postPatch = ''
  35     patchShebangs .
  36     substituteInPlace Makefile \
  37       --replace "pytest-3" "pytest --verbose" \
  38       --replace "INITRAMFS_DIR=/etc/initramfs-tools" \
  39                 "INITRAMFS_DIR=${placeholder "out"}/etc/initramfs-tools"
  40   '';
  41
  42   nativeBuildInputs = [ pkg-config docutils python3Packages.python ];
  43
  44   buildInputs = [
  45     libuuid libscrypt libsodium keyutils liburcu zlib libaio
  46     zstd lz4 python3Packages.pytest udev valgrind
  47   ] ++ lib.optional fuseSupport fuse3;
  48
  49   doCheck = false; # needs bcachefs module loaded on builder
  50   checkFlags = [ "BCACHEFS_TEST_USE_VALGRIND=no" ];
  51   checkInputs = [ valgrind ];
  52
  53   preCheck = lib.optionalString fuseSupport ''
  54     rm tests/test_fuse.py
  55   '';
  56
  57   installFlags = [ "PREFIX=${placeholder "out"}" ];
  58
  59   passthru.tests = {
  60     smoke-test = nixosTests.bcachefs;
  61     inherit (nixosTests.installer) bcachefsSimple bcachefsEncrypted bcachefsMulti;
  62   };
  63
  64   enableParallelBuilding = true;
  65
  66   meta = with lib; {
  67     description = "Tool for managing bcachefs filesystems";
  68     homepage = "https://bcachefs.org/";
  69     license = licenses.gpl2;
  70     maintainers = with maintainers; [ davidak Madouura ];
  71     platforms = platforms.linux;
  72   };
  73 }