pkgs/tools/games/jpsxdec/default.nix

   1 { stdenv
   2 , lib
   3 , fetchFromGitHub
   4 , jdk
   5 /*
   6  * jPSXdec needs to be built with no later than JDK8, but
   7  * should be run with the latest to get HiDPI fixes, etc.
   8  */
   9 , jre ? jdk
  10 , ant
  11 , unoconv
  12 , makeWrapper
  13 , makeDesktopItem
  14 }:
  15 let
  16   pname = "jpsxdec";
  17   version = "1.05";
  18
  19   description = "Cross-platform PlayStation 1 audio and video converter";
  20
  21   desktopItem = makeDesktopItem {
  22     name = pname;
  23     exec = pname;
  24     icon = pname;
  25     comment = description;
  26     desktopName = "jPSXdec";
  27     categories = [ "AudioVideo" "Utility" ];
  28   };
  29 in
  30 stdenv.mkDerivation rec {
  31   inherit pname version;
  32
  33   src = fetchFromGitHub {
  34     owner = "m35";
  35     repo = pname;
  36     rev = "v${version}";
  37     sha256 = "0wnfvvcyldf699b08lzlc0gshl7rn09a6q4i7jmr41izlcdszdbz";
  38   };
  39
  40   nativeBuildInputs = [ ant jdk unoconv makeWrapper ];
  41   buildInputs = [ jre ];
  42
  43   patches = [
  44     ./0001-jpsxdec-hackfix-build-with-newer-JDKs.patch
  45   ];
  46
  47   buildPhase = ''
  48     runHook preBuild
  49
  50     cd jpsxdec
  51     mkdir -p _ant/release/doc/
  52     unoconv -d document -f pdf -o _ant/release/doc/jPSXdec-manual.pdf doc/jPSXdec-manual.odt
  53
  54     ant release
  55
  56     runHook postBuild
  57   '';
  58
  59   installPhase = ''
  60     runHook preInstall
  61
  62     mkdir -p $out/{bin,share/pixmaps}
  63     mv _ant/release $out/jpsxdec
  64
  65     makeWrapper ${jre}/bin/java $out/bin/jpsxdec \
  66       --add-flags "-jar $out/jpsxdec/jpsxdec.jar"
  67
  68     cp ${src}/jpsxdec/src/jpsxdec/gui/icon48.png $out/share/pixmaps/${pname}.png
  69     ln -s ${desktopItem}/share/applications $out/share
  70
  71     runHook postInstall
  72   '';
  73
  74   meta = with lib; {
  75     inherit description;
  76     homepage = "https://jpsxdec.blogspot.com/";
  77     platforms = platforms.all;
  78     license = {
  79       url = "https://raw.githubusercontent.com/m35/jpsxdec/readme/.github/LICENSE.md";
  80       free = true;
  81     };
  82     maintainers = with maintainers; [ zane ];
  83   };
  84 }