pkgs/tools/misc/arch-install-scripts/default.nix

   1 { lib
   2 , resholve
   3 , fetchFromGitHub
   4 , asciidoc
   5 , bash
   6 , coreutils
   7 , gawk
   8 , gnugrep
   9 , gnum4
  10 , makeWrapper
  11 , pacman
  12 , util-linux
  13 , chrootPath ? [
  14     "/usr/local/sbin"
  15     "/usr/local/bin"
  16     "/usr/bin"
  17     "/usr/bin/site_perl"
  18     "/usr/bin/vendor_perl"
  19     "/usr/bin/core_perl"
  20   ]
  21 }:
  22
  23 resholve.mkDerivation rec {
  24   pname = "arch-install-scripts";
  25   version = "27";
  26
  27   src = fetchFromGitHub {
  28     owner = "archlinux";
  29     repo = "arch-install-scripts";
  30     rev = "v${version}";
  31     hash = "sha256-owJImToG8GIk1TfkSKJyXCu9RTJ1qYlvQ6DTMSazaeQ=";
  32   };
  33
  34   nativeBuildInputs = [ asciidoc gnum4 ];
  35
  36   postPatch = ''
  37     substituteInPlace ./Makefile \
  38       --replace "PREFIX = /usr/local" "PREFIX ?= /usr/local"
  39     substituteInPlace ./pacstrap.in \
  40       --replace "cp -a" "cp -LR --no-preserve=mode" \
  41       --replace "unshare pacman" "unshare ${pacman}/bin/pacman" \
  42       --replace 'gnupg "$newroot/etc/pacman.d/"' 'gnupg "$newroot/etc/pacman.d/" && chmod 700 "$newroot/etc/pacman.d/gnupg"'
  43     echo "export PATH=${lib.strings.makeSearchPath "" chrootPath}:\$PATH" >> ./common
  44   '';
  45
  46   installFlags = [ "PREFIX=$(out)" ];
  47
  48   doCheck = true;
  49
  50   solutions = {
  51     # Give each solution a short name. This is what you'd use to
  52     # override its settings, and it shows in (some) error messages.
  53     profile = {
  54       # the only *required* arguments are the 3 below
  55
  56       # Specify 1 or more $out-relative script paths. Unlike many
  57       # builders, resholve.mkDerivation modifies the output files during
  58       # fixup (to correctly resolve in-package sourcing).
  59       scripts = [ "bin/arch-chroot" "bin/genfstab" "bin/pacstrap" ];
  60
  61       # "none" for no shebang, "${bash}/bin/bash" for bash, etc.
  62       interpreter = "${bash}/bin/bash";
  63
  64       # packages resholve should resolve executables from
  65       inputs = [ coreutils gawk gnugrep pacman util-linux ];
  66
  67       execer = [ "cannot:${pacman}/bin/pacman-key" ];
  68
  69       # TODO: no good way to resolve mount/umount in Nix builds for now
  70       # see https://github.com/abathur/resholve/issues/29
  71       fake = {
  72         external = [ "mount" "umount" ];
  73       };
  74
  75       keep = [ "$setup" "$pid_unshare" "$mount_unshare" "${pacman}/bin/pacman" ];
  76     };
  77   };
  78
  79   meta = with lib; {
  80     description = "Useful scripts for installing Arch Linux";
  81     longDescription = ''
  82       A small suite of scripts aimed at automating some menial tasks when installing Arch Linux.
  83     '';
  84     homepage = "https://github.com/archlinux/arch-install-scripts";
  85     license = licenses.gpl2Only;
  86     maintainers = with maintainers; [ samlukeyes123 ];
  87     platforms = platforms.linux;
  88   };
  89 }