pkgs/tools/misc/bat/default.nix

   1 { lib
   2 , stdenv
   3 , rustPlatform
   4 , fetchFromGitHub
   5 , pkg-config
   6 , less
   7 , Security
   8 , libiconv
   9 , installShellFiles
  10 , makeWrapper
  11 }:
  12
  13 rustPlatform.buildRustPackage rec {
  14   pname = "bat";
  15   version = "0.22.1";
  16
  17   src = fetchFromGitHub {
  18     owner = "sharkdp";
  19     repo = pname;
  20     rev = "v${version}";
  21     sha256 = "sha256-xkGGnWjuZ5ZR4Ll+JwgWyKZFboFZ6HKA8GviR3YBAnM=";
  22   };
  23   cargoSha256 = "sha256-ye6GH4pcI9h1CNpobUzfJ+2WlqJ98saCdD77AtSGafg=";
  24
  25   nativeBuildInputs = [ pkg-config installShellFiles makeWrapper ];
  26
  27   buildInputs = lib.optionals stdenv.isDarwin [ Security libiconv ];
  28
  29   postInstall = ''
  30     installManPage $releaseDir/build/bat-*/out/assets/manual/bat.1
  31     installShellCompletion $releaseDir/build/bat-*/out/assets/completions/bat.{bash,fish,zsh}
  32   '';
  33
  34   # Insert Nix-built `less` into PATH because the system-provided one may be too old to behave as
  35   # expected with certain flag combinations.
  36   postFixup = ''
  37     wrapProgram "$out/bin/bat" \
  38       --prefix PATH : "${lib.makeBinPath [ less ]}"
  39   '';
  40
  41   checkFlags = [ "--skip=pager_more" "--skip=pager_most" ];
  42
  43   doInstallCheck = true;
  44   installCheckPhase = ''
  45     runHook preInstallCheck
  46
  47     testFile=$(mktemp /tmp/bat-test.XXXX)
  48     echo -ne 'Foobar\n\n\n42' > $testFile
  49     $out/bin/bat -p $testFile | grep "Foobar"
  50     $out/bin/bat -p $testFile -r 4:4 | grep 42
  51     rm $testFile
  52
  53     runHook postInstallCheck
  54   '';
  55
  56   meta = with lib; {
  57     description = "A cat(1) clone with syntax highlighting and Git integration";
  58     homepage = "https://github.com/sharkdp/bat";
  59     changelog = "https://github.com/sharkdp/bat/raw/v${version}/CHANGELOG.md";
  60     license = with licenses; [ asl20 /* or */ mit ];
  61     maintainers = with maintainers; [ dywedir lilyball zowoq SuperSandro2000 ];
  62   };
  63 }