pkgs/tools/misc/edk2-uefi-shell/default.nix

   1 { lib
   2 , stdenv
   3 , edk2
   4 , llvmPackages
   5 , util-linux
   6 , nasm
   7 , python3
   8 }:
   9 edk2.mkDerivation "ShellPkg/ShellPkg.dsc" (finalAttrs: {
  10   pname = "edk2-uefi-shell";
  11   inherit (edk2) version;
  12
  13   nativeBuildInputs = [ util-linux nasm python3 ]
  14     ++ lib.optionals stdenv.cc.isClang [ llvmPackages.bintools llvmPackages.llvm ];
  15   strictDeps = true;
  16
  17   NIX_CFLAGS_COMPILE = lib.optionals stdenv.cc.isClang [ "-fno-pic" "-Qunused-arguments" ];
  18
  19   # We only have a .efi file in $out which shouldn't be patched or stripped
  20   dontPatchELF = true;
  21   dontStrip = true;
  22
  23   # GUID hardcoded to match ShellPkg.dsc
  24   installPhase = ''
  25     runHook preInstall
  26     install -D -m0644 Build/Shell/RELEASE*/*/Shell_EA4BB293-2D7F-4456-A681-1F22F42CD0BC.efi $out/shell.efi
  27     runHook postInstall
  28   '';
  29
  30   passthru.efi = "${finalAttrs.finalPackage}/shell.efi";
  31
  32   meta = {
  33     inherit (edk2.meta) license platforms;
  34     description = "UEFI Shell from Tianocore EFI development kit";
  35     homepage = "https://github.com/tianocore/tianocore.github.io/wiki/ShellPkg";
  36     maintainers = with lib.maintainers; [ LunNova ];
  37   };
  38 })