pkgs/tools/misc/findutils/default.nix

   1 { lib, stdenv, fetchurl
   2 , coreutils
   3 }:
   4
   5 # Note: this package is used for bootstrapping fetchurl, and thus
   6 # cannot use fetchpatch! All mutable patches (generated by GitHub or
   7 # cgit) that are needed here should be included directly in Nixpkgs as
   8 # files.
   9
  10 stdenv.mkDerivation rec {
  11   pname = "findutils";
  12   version = "4.9.0";
  13
  14   src = fetchurl {
  15     url = "mirror://gnu/findutils/${pname}-${version}.tar.xz";
  16     sha256 = "sha256-or+4wJ1DZ3DtxZ9Q+kg+eFsWGjt7nVR1c8sIBl/UYv4=";
  17   };
  18
  19   postPatch = ''
  20     substituteInPlace xargs/xargs.c --replace 'char default_cmd[] = "echo";' 'char default_cmd[] = "${coreutils}/bin/echo";'
  21   '';
  22
  23   patches = [ ./no-install-statedir.patch ];
  24
  25   buildInputs = [ coreutils ]; # bin/updatedb script needs to call sort
  26
  27   # Since glibc-2.25 the i686 tests hang reliably right after test-sleep.
  28   doCheck
  29     =  !stdenv.hostPlatform.isDarwin
  30     && !(stdenv.hostPlatform.libc == "glibc" && stdenv.hostPlatform.isi686)
  31     && (stdenv.hostPlatform.libc != "musl")
  32     && stdenv.hostPlatform == stdenv.buildPlatform;
  33
  34   outputs = [ "out" "info" "locate"];
  35
  36   configureFlags = [
  37     # "sort" need not be on the PATH as a run-time dep, so we need to tell
  38     # configure where it is. Covers the cross and native case alike.
  39     "SORT=${coreutils}/bin/sort"
  40     "--localstatedir=/var/cache"
  41   ];
  42
  43   CFLAGS = lib.optionals stdenv.isDarwin [
  44     # TODO: Revisit upstream issue https://savannah.gnu.org/bugs/?59972
  45     # https://github.com/Homebrew/homebrew-core/pull/69761#issuecomment-770268478
  46     "-D__nonnull\\(params\\)="
  47   ];
  48
  49   postInstall = ''
  50     moveToOutput bin/locate $locate
  51     moveToOutput bin/updatedb $locate
  52   '';
  53
  54   # can't move man pages in postInstall because the multi-output hook will move them back to $out
  55   postFixup = ''
  56     moveToOutput share/man/man5 $locate
  57     moveToOutput share/man/man1/locate.1.gz $locate
  58     moveToOutput share/man/man1/updatedb.1.gz $locate
  59   '';
  60
  61   enableParallelBuilding = true;
  62
  63   meta = {
  64     homepage = "https://www.gnu.org/software/findutils/";
  65     description = "GNU Find Utilities, the basic directory searching utilities of the GNU operating system";
  66
  67     longDescription = ''
  68       The GNU Find Utilities are the basic directory searching
  69       utilities of the GNU operating system.  These programs are
  70       typically used in conjunction with other programs to provide
  71       modular and powerful directory search and file locating
  72       capabilities to other commands.
  73
  74       The tools supplied with this package are:
  75
  76           * find - search for files in a directory hierarchy;
  77           * xargs - build and execute command lines from standard input.
  78
  79       The following are available in the locate output:
  80
  81           * locate - list files in databases that match a pattern;
  82           * updatedb - update a file name database;
  83     '';
  84
  85     platforms = lib.platforms.all;
  86
  87     license = lib.licenses.gpl3Plus;
  88   };
  89 }