pkgs/tools/misc/geteltorito/default.nix

   1 { lib, stdenv, perl, ronn, fetchurl }:
   2
   3 stdenv.mkDerivation rec {
   4   pname = "geteltorito";
   5   version = "0.6";
   6
   7   src = fetchurl {
   8     url = "https://userpages.uni-koblenz.de/~krienke/ftp/noarch/geteltorito/geteltorito-${version}.tar.gz";
   9     sha256 = "1gkbm9ahj2mgqrkrfpibzclsriqgsbsvjh19fr815vpd9f6snkxv";
  10   };
  11
  12   buildInputs = [ perl ronn ];
  13
  14   unpackCmd = "";
  15   dontBuild = true;
  16   configurePhase = "";
  17   installPhase = ''
  18     # reformat README to ronn markdown
  19     cat > README.new <<EOF
  20     geteltorito -- ${meta.description}
  21     ===========
  22
  23     ## SYNOPSIS
  24
  25     EOF
  26
  27     # skip the first two lines
  28     # -e reformat function call
  29     # -e reformat example
  30     # -e make everything else (that is no code) that contains `: ` a list item
  31     tail -n +3 README | sed \
  32         -e 's/^\(call:\s*\)\(getelt.*\)$/\1`\2`/' \
  33         -e 's/^\(example:\s*\)\(getelt.*\)$/\1 `\2`/' \
  34         -e 's/^\(.*: \)/- \1/g' \
  35            >> README.new
  36     mkdir -p $out/man/man1
  37     ronn --roff README.new --pipe > $out/man/man1/geteltorito.1
  38     install -vD geteltorito $out/bin/geteltorito
  39   '';
  40
  41   meta = with lib; {
  42     description = "Extract the initial/default boot image from a CD image if existent";
  43     homepage = "https://userpages.uni-koblenz.de/~krienke/ftp/noarch/geteltorito/";
  44     maintainers = [ maintainers.Profpatsch ];
  45     license = licenses.gpl2;
  46   };
  47
  48 }