pkgs/tools/misc/man-db/default.nix

   1 { buildPackages
   2 , db
   3 , fetchurl
   4 , groff
   5 , gzip
   6 , lib
   7 , libiconv
   8 , libpipeline
   9 , makeWrapper
  10 , nixosTests
  11 , pkg-config
  12 , stdenv
  13 , zstd
  14 , autoreconfHook
  15 }:
  16
  17 stdenv.mkDerivation rec {
  18   pname = "man-db";
  19   version = "2.10.2";
  20
  21   src = fetchurl {
  22     url = "mirror://savannah/man-db/man-db-${version}.tar.xz";
  23     sha256 = "sha256-7peVTUkqE3MZA8nQcnubAeUIntvWlfDNtY1AWlr1UU0=";
  24   };
  25
  26   outputs = [ "out" "doc" ];
  27   outputMan = "out"; # users will want `man man` to work
  28
  29   strictDeps = true;
  30   nativeBuildInputs = [ autoreconfHook groff makeWrapper pkg-config zstd ];
  31   buildInputs = [ libpipeline db groff ]; # (Yes, 'groff' is both native and build input)
  32   checkInputs = [ libiconv /* for 'iconv' binary */ ];
  33
  34   patches = [ ./systemwide-man-db-conf.patch ];
  35
  36   postPatch = ''
  37     # Remove all mandatory manpaths. Nixpkgs makes no requirements on
  38     # these directories existing.
  39     sed -i 's/^MANDATORY_MANPATH/# &/' src/man_db.conf.in
  40
  41     # Add Nix-related manpaths
  42     echo "MANPATH_MAP   /nix/var/nix/profiles/default/bin       /nix/var/nix/profiles/default/share/man" >> src/man_db.conf.in
  43
  44     # Add mandb locations for the above
  45     echo "MANDB_MAP     /nix/var/nix/profiles/default/share/man /var/cache/man/nixpkgs" >> src/man_db.conf.in
  46   '';
  47
  48   configureFlags = [
  49     "--disable-setuid"
  50     "--disable-cache-owner"
  51     "--localstatedir=/var"
  52     "--with-config-file=${placeholder "out"}/etc/man_db.conf"
  53     "--with-systemdtmpfilesdir=${placeholder "out"}/lib/tmpfiles.d"
  54     "--with-systemdsystemunitdir=${placeholder "out"}/lib/systemd/system"
  55     "--with-pager=less"
  56   ] ++ lib.optionals stdenv.hostPlatform.isDarwin [
  57     "ac_cv_func__set_invalid_parameter_handler=no"
  58     "ac_cv_func_posix_fadvise=no"
  59     "ac_cv_func_mempcpy=no"
  60   ];
  61
  62   preConfigure = ''
  63     configureFlagsArray+=("--with-sections=1 n l 8 3 0 2 5 4 9 6 7")
  64   '';
  65
  66   postInstall = ''
  67     # apropos/whatis uses program name to decide whether to act like apropos or whatis
  68     # (multi-call binary). `apropos` is actually just a symlink to whatis. So we need to
  69     # make sure that we don't wrap symlinks (since that changes argv[0] to the -wrapped name)
  70     find "$out/bin" -type f | while read file; do
  71       wrapProgram "$file" \
  72         --prefix PATH : "${lib.makeBinPath [ groff gzip zstd ]}"
  73     done
  74   '';
  75
  76   disallowedReferences = lib.optionals (stdenv.hostPlatform != stdenv.buildPlatform) [
  77     buildPackages.groff
  78   ];
  79
  80   enableParallelBuilding = true;
  81
  82   doCheck = !stdenv.hostPlatform.isMusl /* iconv binary */ && !stdenv.hostPlatform.isDarwin;
  83
  84   passthru.tests = {
  85     nixos = nixosTests.man;
  86   };
  87
  88   meta = with lib; {
  89     homepage = "http://man-db.nongnu.org";
  90     description = "An implementation of the standard Unix documentation system accessed using the man command";
  91     license = licenses.gpl2;
  92     platforms = lib.platforms.unix;
  93     mainProgram = "man";
  94   };
  95 }