pkgs/tools/misc/memtest86+/default.nix

   1 { lib, stdenv, fetchFromGitHub }:
   2
   3 stdenv.mkDerivation (finalAttrs: {
   4   pname = "memtest86+";
   5   version = "6.00";
   6
   7   src = fetchFromGitHub {
   8     owner = "memtest86plus";
   9     repo = "memtest86plus";
  10     rev = "v${finalAttrs.version}";
  11     hash = "sha256-m9oGLXTCaE5CgA4o8MGdjQTQSz/j8kC9BJ84RVcBZjs=";
  12   };
  13
  14   # Binaries are booted directly by BIOS/UEFI or bootloader
  15   # and should not be patched/stripped
  16   dontPatchELF = true;
  17   dontStrip = true;
  18
  19   passthru.efi = "${finalAttrs.finalPackage}/memtest.efi";
  20
  21   preBuild = ''
  22     cd ${if stdenv.isi686 then "build32" else "build64"}
  23   '';
  24
  25   installPhase = ''
  26     install -Dm0444 -t $out/ memtest.bin memtest.efi
  27   '';
  28
  29   meta = {
  30     homepage = "http://www.memtest.org/";
  31     description = "A tool to detect memory errors";
  32     license = lib.licenses.gpl2;
  33     platforms = [ "x86_64-linux" "i686-linux" ];
  34     maintainers = [ lib.maintainers.LunNova ];
  35   };
  36 })