pkgs/tools/networking/mozillavpn/default.nix

   1 { buildGoModule
   2 , cmake
   3 , fetchFromGitHub
   4 , go
   5 , lib
   6 , pkg-config
   7 , polkit
   8 , python3
   9 , qt5compat
  10 , qtbase
  11 , qtcharts
  12 , qtnetworkauth
  13 , qttools
  14 , qtwebsockets
  15 , rustPlatform
  16 , stdenv
  17 , which
  18 , wireguard-tools
  19 , wrapQtAppsHook
  20 }:
  21
  22 let
  23   pname = "mozillavpn";
  24   version = "2.10.1";
  25   src = fetchFromGitHub {
  26     owner = "mozilla-mobile";
  27     repo = "mozilla-vpn-client";
  28     rev = "v${version}";
  29     fetchSubmodules = true;
  30     hash = "sha256-am2acceDig7tjhkO5GiWfvkq0Mabyxedbc8mR49SXBU=";
  31   };
  32
  33   netfilter-go-modules = (buildGoModule {
  34     inherit pname version src;
  35     modRoot = "linux/netfilter";
  36     vendorHash = "sha256-Cmo0wnl0z5r1paaEf1MhCPbInWeoMhGjnxCxGh0cyO8=";
  37   }).go-modules;
  38
  39   extensionBridgeDeps = rustPlatform.fetchCargoTarball {
  40     inherit src;
  41     name = "${pname}-${version}-extension-bridge";
  42     preBuild = "cd extension/bridge";
  43     hash = "sha256-sw6iylh3SgCDA1z/xvwNGWrCU2xr7IVPUL4fdOi43lc=";
  44   };
  45
  46   signatureDeps = rustPlatform.fetchCargoTarball {
  47     inherit src;
  48     name = "${pname}-${version}-signature";
  49     preBuild = "cd signature";
  50     hash = "sha256-gBJIzTTo6i415aHwUsBriokUt2K/r55QCpC6Tv8GXh4=";
  51   };
  52
  53 in
  54 stdenv.mkDerivation {
  55   inherit pname version src;
  56
  57   buildInputs = [
  58     polkit
  59     qt5compat
  60     qtbase
  61     qtcharts
  62     qtnetworkauth
  63     qtwebsockets
  64   ];
  65   nativeBuildInputs = [
  66     cmake
  67     go
  68     pkg-config
  69     python3
  70     python3.pkgs.glean-parser
  71     python3.pkgs.lxml
  72     python3.pkgs.pyyaml
  73     python3.pkgs.setuptools
  74     rustPlatform.cargoSetupHook
  75     rustPlatform.rust.cargo
  76     which
  77     wrapQtAppsHook
  78   ];
  79
  80   postUnpack = ''
  81     pushd source/extension/bridge
  82     cargoDeps='${extensionBridgeDeps}' cargoSetupPostUnpackHook
  83     extensionBridgeDepsCopy="$cargoDepsCopy"
  84     popd
  85
  86     pushd source/signature
  87     cargoDeps='${signatureDeps}' cargoSetupPostUnpackHook
  88     signatureDepsCopy="$cargoDepsCopy"
  89     popd
  90   '';
  91   dontCargoSetupPostUnpack = true;
  92
  93   postPatch = ''
  94     for file in linux/*.service linux/extra/*.desktop src/platforms/linux/daemon/*.service; do
  95       substituteInPlace "$file" --replace /usr/bin/mozillavpn "$out/bin/mozillavpn"
  96     done
  97
  98     substituteInPlace scripts/addon/build.py \
  99       --replace 'qtbinpath = args.qtpath' 'qtbinpath = "${qttools.dev}/bin"' \
 100       --replace 'rcc = os.path.join(qtbinpath, rcc_bin)' 'rcc = "${qtbase.dev}/libexec/rcc"'
 101
 102     substituteInPlace src/cmake/linux.cmake \
 103       --replace '/etc/xdg/autostart' "$out/etc/xdg/autostart" \
 104       --replace '${"$"}{POLKIT_POLICY_DIR}' "$out/share/polkit-1/actions" \
 105       --replace '/usr/share/dbus-1' "$out/share/dbus-1" \
 106       --replace '${"$"}{SYSTEMD_UNIT_DIR}' "$out/lib/systemd/system"
 107
 108     substituteInPlace extension/CMakeLists.txt \
 109       --replace '/etc' "$out/etc"
 110
 111     substituteInPlace src/connectionbenchmark/benchmarktaskdownload.cpp \
 112       --replace 'QT_VERSION >= 0x060400' 'false'
 113
 114     ln -s '${netfilter-go-modules}' linux/netfilter/vendor
 115
 116     pushd extension/bridge
 117     cargoDepsCopy="$extensionBridgeDepsCopy" cargoSetupPostPatchHook
 118     popd
 119
 120     pushd signature
 121     cargoDepsCopy="$signatureDepsCopy" cargoSetupPostPatchHook
 122     popd
 123
 124     cargoSetupPostPatchHook() { true; }
 125   '';
 126
 127   cmakeFlags = [
 128     "-DQT_LCONVERT_EXECUTABLE=${qttools.dev}/bin/lconvert"
 129     "-DQT_LUPDATE_EXECUTABLE=${qttools.dev}/bin/lupdate"
 130     "-DQT_LRELEASE_EXECUTABLE=${qttools.dev}/bin/lrelease"
 131   ];
 132   dontFixCmake = true;
 133
 134   qtWrapperArgs =
 135     [ "--prefix" "PATH" ":" (lib.makeBinPath [ wireguard-tools ]) ];
 136
 137   meta = {
 138     description = "Client for the Mozilla VPN service";
 139     homepage = "https://vpn.mozilla.org/";
 140     license = lib.licenses.mpl20;
 141     maintainers = with lib.maintainers; [ andersk ];
 142     platforms = lib.platforms.linux;
 143   };
 144 }