pkgs/tools/networking/openfortivpn/default.nix

   1 { stdenv, lib, fetchFromGitHub, autoreconfHook, pkg-config
   2 , openssl
   3 , ppp
   4 , systemd
   5 , withSystemd ? stdenv.isLinux
   6 , withPpp ? stdenv.isLinux
   7 }:
   8
   9 stdenv.mkDerivation rec {
  10   pname = "openfortivpn";
  11   version = "1.17.3";
  12
  13   src = fetchFromGitHub {
  14     owner = "adrienverge";
  15     repo = pname;
  16     rev = "v${version}";
  17     sha256 = "sha256-VGjzxEdWnGICpGWBklYoAqhC4ka1rF/a6K17hoFDxSo=";
  18   };
  19
  20   # we cannot write the config file to /etc and as we don't need the file, so drop it
  21   postPatch = ''
  22     substituteInPlace Makefile.am \
  23       --replace '$(DESTDIR)$(confdir)' /tmp
  24   '';
  25
  26   nativeBuildInputs = [ autoreconfHook pkg-config ];
  27
  28   buildInputs = [
  29     openssl
  30   ]
  31   ++ lib.optional withSystemd systemd
  32   ++ lib.optional withPpp ppp;
  33
  34   configureFlags = [
  35     "--sysconfdir=/etc"
  36   ]
  37   ++ lib.optional withSystemd "--with-systemdsystemunitdir=${placeholder "out"}/lib/systemd/system"
  38   ++ lib.optional withPpp "--with-pppd=${ppp}/bin/pppd";
  39
  40   enableParallelBuilding = true;
  41
  42   meta = with lib; {
  43     description = "Client for PPP+SSL VPN tunnel services";
  44     homepage = "https://github.com/adrienverge/openfortivpn";
  45     license = licenses.gpl3;
  46     maintainers = with maintainers; [ madjar ];
  47     platforms = with platforms; linux ++ darwin;
  48   };
  49 }