pkgs/tools/networking/openssh/common.nix

   1 { pname
   2 , version
   3 , extraDesc ? ""
   4 , src
   5 , extraPatches ? []
   6 , extraNativeBuildInputs ? []
   7 , extraConfigureFlags ? []
   8 , extraMeta ? {}
   9 }:
  10
  11 { lib, stdenv
  12 # This *is* correct, though unusual. as a way of getting krb5-config from the
  13 # package without splicing See: https://github.com/NixOS/nixpkgs/pull/107606
  14 , pkgs
  15 , fetchurl
  16 , fetchpatch
  17 , zlib
  18 , openssl
  19 , libedit
  20 , pkg-config
  21 , pam
  22 , libredirect
  23 , etcDir ? null
  24 , withKerberos ? true
  25 , libkrb5
  26 , libfido2
  27 , hostname
  28 , nixosTests
  29 , withFIDO ? stdenv.hostPlatform.isUnix && !stdenv.hostPlatform.isMusl
  30 , linkOpenssl ? true
  31 }:
  32
  33 with lib;
  34 stdenv.mkDerivation rec {
  35   inherit pname version src;
  36
  37   patches = [
  38     ./locale_archive.patch
  39
  40     (fetchurl {
  41       url = "https://git.alpinelinux.org/aports/plain/main/openssh/gss-serv.c.patch?id=a7509603971ce2f3282486a43bb773b1b522af83";
  42       sha256 = "sha256-eFFOd4B2nccRZAQWwdBPBoKWjfEdKEVGJvKZAzLu3HU=";
  43     })
  44
  45     # See discussion in https://github.com/NixOS/nixpkgs/pull/16966
  46     ./dont_create_privsep_path.patch
  47   ] ++ extraPatches;
  48
  49   postPatch =
  50     # On Hydra this makes installation fail (sometimes?),
  51     # and nix store doesn't allow such fancy permission bits anyway.
  52     ''
  53       substituteInPlace Makefile.in --replace '$(INSTALL) -m 4711' '$(INSTALL) -m 0711'
  54     '';
  55
  56   nativeBuildInputs = [ pkg-config ]
  57     # This is not the same as the libkrb5 from the inputs! pkgs.libkrb5 is
  58     # needed here to access krb5-config in order to cross compile. See:
  59     # https://github.com/NixOS/nixpkgs/pull/107606
  60     ++ optional withKerberos pkgs.libkrb5
  61     ++ extraNativeBuildInputs;
  62   buildInputs = [ zlib openssl libedit ]
  63     ++ optional withFIDO libfido2
  64     ++ optional withKerberos libkrb5
  65     ++ optional stdenv.isLinux pam;
  66
  67   preConfigure = ''
  68     # Setting LD causes `configure' and `make' to disagree about which linker
  69     # to use: `configure' wants `gcc', but `make' wants `ld'.
  70     unset LD
  71   '';
  72
  73   # I set --disable-strip because later we strip anyway. And it fails to strip
  74   # properly when cross building.
  75   configureFlags = [
  76     "--sbindir=\${out}/bin"
  77     "--localstatedir=/var"
  78     "--with-pid-dir=/run"
  79     "--with-mantype=man"
  80     "--with-libedit=yes"
  81     "--disable-strip"
  82     (if stdenv.isLinux then "--with-pam" else "--without-pam")
  83   ] ++ optional (etcDir != null) "--sysconfdir=${etcDir}"
  84     ++ optional withFIDO "--with-security-key-builtin=yes"
  85     ++ optional withKerberos (assert libkrb5 != null; "--with-kerberos5=${libkrb5}")
  86     ++ optional stdenv.isDarwin "--disable-libutil"
  87     ++ optional (!linkOpenssl) "--without-openssl"
  88     ++ extraConfigureFlags;
  89
  90   ${if stdenv.hostPlatform.isStatic then "NIX_LDFLAGS" else null}= [ "-laudit" ] ++ lib.optionals withKerberos [ "-lkeyutils" ];
  91
  92   buildFlags = [ "SSH_KEYSIGN=ssh-keysign" ];
  93
  94   enableParallelBuilding = true;
  95
  96   hardeningEnable = [ "pie" ];
  97
  98   doCheck = true;
  99   enableParallelChecking = false;
 100   checkInputs = optional (!stdenv.isDarwin) hostname;
 101   preCheck = lib.optionalString (stdenv.hostPlatform == stdenv.buildPlatform) ''
 102     # construct a dummy HOME
 103     export HOME=$(realpath ../dummy-home)
 104     mkdir -p ~/.ssh
 105
 106     # construct a dummy /etc/passwd file for the sshd under test
 107     # to use to look up the connecting user
 108     DUMMY_PASSWD=$(realpath ../dummy-passwd)
 109     cat > $DUMMY_PASSWD <<EOF
 110     $(whoami)::$(id -u):$(id -g)::$HOME:$SHELL
 111     EOF
 112
 113     # we need to NIX_REDIRECTS /etc/passwd both for processes
 114     # invoked directly and those invoked by the "remote" session
 115     cat > ~/.ssh/environment.base <<EOF
 116     NIX_REDIRECTS=/etc/passwd=$DUMMY_PASSWD
 117     LD_PRELOAD=${libredirect}/lib/libredirect.so
 118     EOF
 119
 120     # use an ssh environment file to ensure environment is set
 121     # up appropriately for build environment even when no shell
 122     # is invoked by the ssh session. otherwise the PATH will
 123     # only contain default unix paths like /bin which we don't
 124     # have in our build environment
 125     cat - regress/test-exec.sh > regress/test-exec.sh.new <<EOF
 126     cp $HOME/.ssh/environment.base $HOME/.ssh/environment
 127     echo "PATH=\$PATH" >> $HOME/.ssh/environment
 128     EOF
 129     mv regress/test-exec.sh.new regress/test-exec.sh
 130
 131     # explicitly enable the PermitUserEnvironment feature
 132     substituteInPlace regress/test-exec.sh \
 133       --replace \
 134         'cat << EOF > $OBJ/sshd_config' \
 135         $'cat << EOF > $OBJ/sshd_config\n\tPermitUserEnvironment yes'
 136
 137     # some tests want to use files under /bin as example files
 138     for f in regress/sftp-cmds.sh regress/forwarding.sh; do
 139       substituteInPlace $f --replace '/bin' "$(dirname $(type -p ls))"
 140     done
 141
 142     # set up NIX_REDIRECTS for direct invocations
 143     set -a; source ~/.ssh/environment.base; set +a
 144   '';
 145   # integration tests hard to get working on darwin with its shaky
 146   # sandbox
 147   # t-exec tests fail on musl
 148   checkTarget = optional (!stdenv.isDarwin && !stdenv.hostPlatform.isMusl) "t-exec"
 149     # other tests are less demanding of the environment
 150     ++ [ "unit" "file-tests" "interop-tests" ];
 151
 152   postInstall = ''
 153     # Install ssh-copy-id, it's very useful.
 154     cp contrib/ssh-copy-id $out/bin/
 155     chmod +x $out/bin/ssh-copy-id
 156     cp contrib/ssh-copy-id.1 $out/share/man/man1/
 157   '';
 158
 159   installTargets = [ "install-nokeys" ];
 160   installFlags = [
 161     "sysconfdir=\${out}/etc/ssh"
 162   ];
 163
 164   passthru.tests = {
 165     borgbackup-integration = nixosTests.borgbackup;
 166   };
 167
 168   meta = {
 169     description = "An implementation of the SSH protocol${extraDesc}";
 170     homepage = "https://www.openssh.com/";
 171     changelog = "https://www.openssh.com/releasenotes.html";
 172     license = licenses.bsd2;
 173     platforms = platforms.unix ++ platforms.windows;
 174     maintainers = (extraMeta.maintainers or []) ++ (with maintainers; [ eelco aneeshusa ]);
 175     mainProgram = "ssh";
 176   } // extraMeta;
 177 }