pkgs/tools/package-management/auditwheel/default.nix

   1 { lib
   2 , bzip2
   3 , patchelf
   4 , python3
   5 , gnutar
   6 , unzip
   7 }:
   8
   9 python3.pkgs.buildPythonApplication rec {
  10   pname = "auditwheel";
  11   version = "5.1.2";
  12   format = "setuptools";
  13
  14   src = python3.pkgs.fetchPypi {
  15     inherit pname version;
  16     hash = "sha256-PuWDABSTHqhK9c0GXGN7ZhTvoD2biL2Pv8kk5+0B1ro=";
  17   };
  18
  19   nativeBuildInputs = with python3.pkgs; [
  20     pbr
  21   ];
  22
  23   propagatedBuildInputs = with python3.pkgs; [
  24     pyelftools
  25     setuptools
  26   ];
  27
  28   checkInputs = with python3.pkgs; [
  29     pretend
  30     pytestCheckHook
  31   ];
  32
  33   # Integration tests require docker and networking
  34   disabledTestPaths = [
  35     "tests/integration"
  36   ];
  37
  38   # Ensure that there are no undeclared deps
  39   postCheck = ''
  40     PATH= PYTHONPATH= $out/bin/auditwheel --version > /dev/null
  41   '';
  42
  43   makeWrapperArgs = [
  44     "--prefix" "PATH" ":" (lib.makeBinPath [ bzip2 gnutar patchelf unzip ])
  45   ];
  46
  47   meta = with lib; {
  48     description = "Auditing and relabeling cross-distribution Linux wheels";
  49     homepage = "https://github.com/pypa/auditwheel";
  50     license = with licenses; [
  51       mit  # auditwheel and nibabel
  52       bsd2  # from https://github.com/matthew-brett/delocate
  53       bsd3  # from https://sources.gentoo.org/cgi-bin/viewvc.cgi/gentoo-projects/pax-utils/lddtree.py
  54     ];
  55     maintainers = with maintainers; [ davhau ];
  56     platforms = platforms.linux;
  57   };
  58 }