nixos/modules/hardware/video/bumblebee.nix

   1 { config, lib, pkgs, ... }:
   2 let
   3   cfg = config.hardware.bumblebee;
   4
   5   kernel = config.boot.kernelPackages;
   6
   7   useNvidia = cfg.driver == "nvidia";
   8
   9   bumblebee = pkgs.bumblebee.override {
  10     inherit useNvidia;
  11     useDisplayDevice = cfg.connectDisplay;
  12   };
  13
  14   useBbswitch = cfg.pmMethod == "bbswitch" || cfg.pmMethod == "auto" && useNvidia;
  15
  16   primus = pkgs.primus.override {
  17     inherit useNvidia;
  18   };
  19
  20 in
  21
  22 {
  23
  24   options = {
  25     hardware.bumblebee = {
  26
  27       enable = lib.mkOption {
  28         default = false;
  29         type = lib.types.bool;
  30         description = ''
  31           Enable the bumblebee daemon to manage Optimus hybrid video cards.
  32           This should power off secondary GPU until its use is requested
  33           by running an application with optirun.
  34         '';
  35       };
  36
  37       group = lib.mkOption {
  38         default = "wheel";
  39         example = "video";
  40         type = lib.types.str;
  41         description = "Group for bumblebee socket";
  42       };
  43
  44       connectDisplay = lib.mkOption {
  45         default = false;
  46         type = lib.types.bool;
  47         description = ''
  48           Set to true if you intend to connect your discrete card to a
  49           monitor. This option will set up your Nvidia card for EDID
  50           discovery and to turn on the monitor signal.
  51
  52           Only nvidia driver is supported so far.
  53         '';
  54       };
  55
  56       driver = lib.mkOption {
  57         default = "nvidia";
  58         type = lib.types.enum [ "nvidia" "nouveau" ];
  59         description = ''
  60           Set driver used by bumblebeed. Supported are nouveau and nvidia.
  61         '';
  62       };
  63
  64       pmMethod = lib.mkOption {
  65         default = "auto";
  66         type = lib.types.enum [ "auto" "bbswitch" "switcheroo" "none" ];
  67         description = ''
  68           Set preferred power management method for unused card.
  69         '';
  70       };
  71
  72     };
  73   };
  74
  75   config = lib.mkIf cfg.enable {
  76     boot.blacklistedKernelModules = [ "nvidia-drm" "nvidia" "nouveau" ];
  77     boot.kernelModules = lib.optional useBbswitch "bbswitch";
  78     boot.extraModulePackages = lib.optional useBbswitch kernel.bbswitch ++ lib.optional useNvidia kernel.nvidia_x11.bin;
  79
  80     environment.systemPackages = [ bumblebee primus ];
  81
  82     systemd.services.bumblebeed = {
  83       description = "Bumblebee Hybrid Graphics Switcher";
  84       wantedBy = [ "multi-user.target" ];
  85       before = [ "display-manager.service" ];
  86       serviceConfig = {
  87         ExecStart = "${bumblebee}/bin/bumblebeed --use-syslog -g ${cfg.group} --driver ${cfg.driver} --pm-method ${cfg.pmMethod}";
  88       };
  89     };
  90   };
  91 }