nixos/modules/services/computing/torque/mom.nix

   1 { config, pkgs, lib, ... }:
   2 let
   3
   4   cfg = config.services.torque.mom;
   5   torque = pkgs.torque;
   6
   7   momConfig = pkgs.writeText "torque-mom-config" ''
   8     $pbsserver ${cfg.serverNode}
   9     $logevent 225
  10   '';
  11
  12 in
  13 {
  14   options = {
  15
  16     services.torque.mom = {
  17       enable = lib.mkEnableOption "torque computing node";
  18
  19       serverNode = lib.mkOption {
  20         type = lib.types.str;
  21         description = "Hostname running pbs server.";
  22       };
  23
  24     };
  25
  26   };
  27
  28   config = lib.mkIf cfg.enable {
  29     environment.systemPackages = [ pkgs.torque ];
  30
  31     systemd.services.torque-mom-init = {
  32       path = with pkgs; [ torque util-linux procps inetutils ];
  33
  34       script = ''
  35         pbs_mkdirs -v aux
  36         pbs_mkdirs -v mom
  37         hostname > /var/spool/torque/server_name
  38         cp -v ${momConfig} /var/spool/torque/mom_priv/config
  39       '';
  40
  41       serviceConfig.Type = "oneshot";
  42       unitConfig.ConditionPathExists = "!/var/spool/torque";
  43     };
  44
  45     systemd.services.torque-mom = {
  46       path = [ torque ];
  47
  48       wantedBy = [ "multi-user.target" ];
  49       requires = [ "torque-mom-init.service" ];
  50       after = [ "torque-mom-init.service" "network.target" ];
  51
  52       serviceConfig = {
  53         Type = "forking";
  54         ExecStart = "${torque}/bin/pbs_mom";
  55         PIDFile = "/var/spool/torque/mom_priv/mom.lock";
  56       };
  57     };
  58
  59   };
  60 }