nixos/modules/services/hardware/bluetooth.nix

   1 {
   2   config,
   3   lib,
   4   pkgs,
   5   ...
   6 }:
   7 let
   8   cfg = config.hardware.bluetooth;
   9   package = cfg.package;
  10
  11   inherit (lib)
  12     mkDefault
  13     mkEnableOption
  14     mkIf
  15     mkOption
  16     mkPackageOption
  17     mkRenamedOptionModule
  18     mkRemovedOptionModule
  19     concatStringsSep
  20     escapeShellArgs
  21     literalExpression
  22     optional
  23     optionals
  24     optionalAttrs
  25     recursiveUpdate
  26     types
  27     ;
  28
  29   cfgFmt = pkgs.formats.ini { };
  30
  31   defaults = {
  32     General.ControllerMode = "dual";
  33     Policy.AutoEnable = cfg.powerOnBoot;
  34   };
  35
  36   hasDisabledPlugins = builtins.length cfg.disabledPlugins > 0;
  37
  38 in
  39 {
  40   imports = [
  41     (mkRenamedOptionModule [ "hardware" "bluetooth" "config" ] [ "hardware" "bluetooth" "settings" ])
  42     (mkRemovedOptionModule [ "hardware" "bluetooth" "extraConfig" ] ''
  43       Use hardware.bluetooth.settings instead.
  44
  45       This is part of the general move to use structured settings instead of raw
  46       text for config as introduced by RFC0042:
  47       https://github.com/NixOS/rfcs/blob/master/rfcs/0042-config-option.md
  48     '')
  49   ];
  50
  51   ###### interface
  52
  53   options = {
  54
  55     hardware.bluetooth = {
  56       enable = mkEnableOption "support for Bluetooth";
  57
  58       hsphfpd.enable = mkEnableOption "support for hsphfpd[-prototype] implementation";
  59
  60       powerOnBoot = mkOption {
  61         type = types.bool;
  62         default = true;
  63         description = "Whether to power up the default Bluetooth controller on boot.";
  64       };
  65
  66       package = mkPackageOption pkgs "bluez" { };
  67
  68       disabledPlugins = mkOption {
  69         type = types.listOf types.str;
  70         default = [ ];
  71         description = "Built-in plugins to disable";
  72       };
  73
  74       settings = mkOption {
  75         type = cfgFmt.type;
  76         default = { };
  77         example = {
  78           General = {
  79             ControllerMode = "bredr";
  80           };
  81         };
  82         description = ''
  83           Set configuration for system-wide bluetooth (/etc/bluetooth/main.conf).
  84           See <https://github.com/bluez/bluez/blob/master/src/main.conf> for full list of options.
  85         '';
  86       };
  87
  88       input = mkOption {
  89         type = cfgFmt.type;
  90         default = { };
  91         example = {
  92           General = {
  93             IdleTimeout = 30;
  94             ClassicBondedOnly = true;
  95           };
  96         };
  97         description = ''
  98           Set configuration for the input service (/etc/bluetooth/input.conf).
  99           See <https://github.com/bluez/bluez/blob/master/profiles/input/input.conf> for full list of options.
 100         '';
 101       };
 102
 103       network = mkOption {
 104         type = cfgFmt.type;
 105         default = { };
 106         example = {
 107           General = {
 108             DisableSecurity = true;
 109           };
 110         };
 111         description = ''
 112           Set configuration for the network service (/etc/bluetooth/network.conf).
 113           See <https://github.com/bluez/bluez/blob/master/profiles/network/network.conf> for full list of options.
 114         '';
 115       };
 116     };
 117   };
 118
 119   ###### implementation
 120
 121   config = mkIf cfg.enable {
 122     environment.systemPackages = [ package ] ++ optional cfg.hsphfpd.enable pkgs.hsphfpd;
 123
 124     environment.etc."bluetooth/input.conf".source = cfgFmt.generate "input.conf" cfg.input;
 125     environment.etc."bluetooth/network.conf".source = cfgFmt.generate "network.conf" cfg.network;
 126     environment.etc."bluetooth/main.conf".source = cfgFmt.generate "main.conf" (
 127       recursiveUpdate defaults cfg.settings
 128     );
 129     services.udev.packages = [ package ];
 130     services.dbus.packages = [ package ] ++ optional cfg.hsphfpd.enable pkgs.hsphfpd;
 131     systemd.packages = [ package ];
 132
 133     systemd.services =
 134       {
 135         bluetooth =
 136           let
 137             # `man bluetoothd` will refer to main.conf in the nix store but bluez
 138             # will in fact load the configuration file at /etc/bluetooth/main.conf
 139             # so force it here to avoid any ambiguity and things suddenly breaking
 140             # if/when the bluez derivation is changed.
 141             args = [
 142               "-f"
 143               "/etc/bluetooth/main.conf"
 144             ] ++ optional hasDisabledPlugins "--noplugin=${concatStringsSep "," cfg.disabledPlugins}";
 145           in
 146           {
 147             wantedBy = [ "bluetooth.target" ];
 148             aliases = [ "dbus-org.bluez.service" ];
 149             serviceConfig.ExecStart = [
 150               ""
 151               "${package}/libexec/bluetooth/bluetoothd ${escapeShellArgs args}"
 152             ];
 153             # restarting can leave people without a mouse/keyboard
 154             unitConfig.X-RestartIfChanged = false;
 155           };
 156       }
 157       // (optionalAttrs cfg.hsphfpd.enable {
 158         hsphfpd = {
 159           after = [ "bluetooth.service" ];
 160           requires = [ "bluetooth.service" ];
 161           wantedBy = [ "bluetooth.target" ];
 162
 163           description = "A prototype implementation used for connecting HSP/HFP Bluetooth devices";
 164           serviceConfig.ExecStart = "${pkgs.hsphfpd}/bin/hsphfpd.pl";
 165         };
 166       });
 167
 168     systemd.user.services =
 169       {
 170         obex.aliases = [ "dbus-org.bluez.obex.service" ];
 171       }
 172       // optionalAttrs cfg.hsphfpd.enable {
 173         telephony_client = {
 174           wantedBy = [ "default.target" ];
 175
 176           description = "telephony_client for hsphfpd";
 177           serviceConfig.ExecStart = "${pkgs.hsphfpd}/bin/telephony_client.pl";
 178         };
 179       };
 180   };
 181 }