nixos/modules/services/monitoring/cockpit.nix

   1 { pkgs, config, lib, ... }:
   2
   3 let
   4   cfg = config.services.cockpit;
   5   inherit (lib) types mkEnableOption mkOption mkIf literalMD mkPackageOption;
   6   settingsFormat = pkgs.formats.ini {};
   7 in {
   8   options = {
   9     services.cockpit = {
  10       enable = mkEnableOption "Cockpit";
  11
  12       package = mkPackageOption pkgs "Cockpit" {
  13         default = [ "cockpit" ];
  14       };
  15
  16       settings = lib.mkOption {
  17         type = settingsFormat.type;
  18
  19         default = {};
  20
  21         description = ''
  22           Settings for cockpit that will be saved in /etc/cockpit/cockpit.conf.
  23
  24           See the [documentation](https://cockpit-project.org/guide/latest/cockpit.conf.5.html), that is also available with `man cockpit.conf.5` for details.
  25         '';
  26       };
  27
  28       port = mkOption {
  29         description = "Port where cockpit will listen.";
  30         type = types.port;
  31         default = 9090;
  32       };
  33
  34       openFirewall = mkOption {
  35         description = "Open port for cockpit.";
  36         type = types.bool;
  37         default = false;
  38       };
  39     };
  40   };
  41   config = mkIf cfg.enable {
  42
  43     # expose cockpit-bridge system-wide
  44     environment.systemPackages = [ cfg.package ];
  45
  46     # allow cockpit to find its plugins
  47     environment.pathsToLink = [ "/share/cockpit" ];
  48
  49     # generate cockpit settings
  50     environment.etc."cockpit/cockpit.conf".source = settingsFormat.generate "cockpit.conf" cfg.settings;
  51
  52     security.pam.services.cockpit = {};
  53
  54     networking.firewall.allowedTCPPorts = mkIf cfg.openFirewall [ cfg.port ];
  55
  56     systemd.packages = [ cfg.package ];
  57     systemd.sockets.cockpit.wantedBy = [ "multi-user.target" ];
  58
  59     systemd.tmpfiles.rules = [ # From $out/lib/tmpfiles.d/cockpit-tmpfiles.conf
  60       "C /run/cockpit/inactive.motd 0640 root root - ${cfg.package}/share/cockpit/motd/inactive.motd"
  61       "f /run/cockpit/active.motd   0640 root root -"
  62       "L+ /run/cockpit/motd - - - - inactive.motd"
  63       "d /etc/cockpit/ws-certs.d 0600 root root 0"
  64     ];
  65   };
  66
  67   meta.maintainers = pkgs.cockpit.meta.maintainers;
  68 }