nixos/modules/services/networking/bird.nix

   1 {
   2   config,
   3   lib,
   4   pkgs,
   5   ...
   6 }:
   7
   8 let
   9   inherit (lib)
  10     mkEnableOption
  11     mkIf
  12     mkOption
  13     optionalString
  14     types
  15     ;
  16
  17   cfg = config.services.bird2;
  18   caps = [
  19     "CAP_NET_ADMIN"
  20     "CAP_NET_BIND_SERVICE"
  21     "CAP_NET_RAW"
  22   ];
  23 in
  24 {
  25   ###### interface
  26   options = {
  27     services.bird2 = {
  28       enable = mkEnableOption "BIRD Internet Routing Daemon";
  29       config = mkOption {
  30         type = types.lines;
  31         description = ''
  32           BIRD Internet Routing Daemon configuration file.
  33           <http://bird.network.cz/>
  34         '';
  35       };
  36       autoReload = mkOption {
  37         type = types.bool;
  38         default = true;
  39         description = ''
  40           Whether bird2 should be automatically reloaded when the configuration changes.
  41         '';
  42       };
  43       checkConfig = mkOption {
  44         type = types.bool;
  45         default = true;
  46         description = ''
  47           Whether the config should be checked at build time.
  48           When the config can't be checked during build time, for example when it includes
  49           other files, either disable this option or use `preCheckConfig` to create
  50           the included files before checking.
  51         '';
  52       };
  53       preCheckConfig = mkOption {
  54         type = types.lines;
  55         default = "";
  56         example = ''
  57           echo "cost 100;" > include.conf
  58         '';
  59         description = ''
  60           Commands to execute before the config file check. The file to be checked will be
  61           available as `bird2.conf` in the current directory.
  62
  63           Files created with this option will not be available at service runtime, only during
  64           build time checking.
  65         '';
  66       };
  67     };
  68   };
  69
  70   imports = [
  71     (lib.mkRemovedOptionModule [ "services" "bird" ] "Use services.bird2 instead")
  72     (lib.mkRemovedOptionModule [ "services" "bird6" ] "Use services.bird2 instead")
  73   ];
  74
  75   ###### implementation
  76   config = mkIf cfg.enable {
  77     environment.systemPackages = [ pkgs.bird ];
  78
  79     environment.etc."bird/bird2.conf".source = pkgs.writeTextFile {
  80       name = "bird2";
  81       text = cfg.config;
  82       checkPhase = optionalString cfg.checkConfig ''
  83         ln -s $out bird2.conf
  84         ${cfg.preCheckConfig}
  85         ${pkgs.buildPackages.bird}/bin/bird -d -p -c bird2.conf
  86       '';
  87     };
  88
  89     systemd.services.bird2 = {
  90       description = "BIRD Internet Routing Daemon";
  91       wantedBy = [ "multi-user.target" ];
  92       reloadTriggers = lib.optional cfg.autoReload config.environment.etc."bird/bird2.conf".source;
  93       serviceConfig = {
  94         Type = "forking";
  95         Restart = "on-failure";
  96         User = "bird2";
  97         Group = "bird2";
  98         ExecStart = "${pkgs.bird}/bin/bird -c /etc/bird/bird2.conf";
  99         ExecReload = "${pkgs.bird}/bin/birdc configure";
 100         ExecStop = "${pkgs.bird}/bin/birdc down";
 101         RuntimeDirectory = "bird";
 102         CapabilityBoundingSet = caps;
 103         AmbientCapabilities = caps;
 104         ProtectSystem = "full";
 105         ProtectHome = "yes";
 106         ProtectKernelTunables = true;
 107         ProtectControlGroups = true;
 108         PrivateTmp = true;
 109         PrivateDevices = true;
 110         SystemCallFilter = "~@cpu-emulation @debug @keyring @module @mount @obsolete @raw-io";
 111         MemoryDenyWriteExecute = "yes";
 112       };
 113     };
 114     users = {
 115       users.bird2 = {
 116         description = "BIRD Internet Routing Daemon user";
 117         group = "bird2";
 118         isSystemUser = true;
 119       };
 120       groups.bird2 = { };
 121     };
 122   };
 123 }