nixos/modules/services/web-servers/varnish/default.nix

   1 { config, lib, pkgs, ...}:
   2
   3 with lib;
   4
   5 let
   6   cfg = config.services.varnish;
   7
   8   commandLine = "-f ${pkgs.writeText "default.vcl" cfg.config}" +
   9       optionalString (cfg.extraModules != []) " -p vmod_path='${makeSearchPathOutput "lib" "lib/varnish/vmods" ([cfg.package] ++ cfg.extraModules)}' -r vmod_path";
  10 in
  11 {
  12   options = {
  13     services.varnish = {
  14       enable = mkEnableOption "Varnish Server";
  15
  16       enableConfigCheck = mkEnableOption "checking the config during build time" // { default = true; };
  17
  18       package = mkPackageOption pkgs "varnish" { };
  19
  20       http_address = mkOption {
  21         type = types.str;
  22         default = "*:6081";
  23         description = ''
  24           HTTP listen address and port.
  25         '';
  26       };
  27
  28       config = mkOption {
  29         type = types.lines;
  30         description = ''
  31           Verbatim default.vcl configuration.
  32         '';
  33       };
  34
  35       stateDir = mkOption {
  36         type = types.path;
  37         default = "/run/varnish/${config.networking.hostName}";
  38         defaultText = literalExpression ''"/run/varnish/''${config.networking.hostName}"'';
  39         description = ''
  40           Directory holding all state for Varnish to run. Note that this should be a tmpfs in order to avoid performance issues and crashes.
  41         '';
  42       };
  43
  44       extraModules = mkOption {
  45         type = types.listOf types.package;
  46         default = [];
  47         example = literalExpression "[ pkgs.varnishPackages.geoip ]";
  48         description = ''
  49           Varnish modules (except 'std').
  50         '';
  51       };
  52
  53       extraCommandLine = mkOption {
  54         type = types.str;
  55         default = "";
  56         example = "-s malloc,256M";
  57         description = ''
  58           Command line switches for varnishd (run 'varnishd -?' to get list of options)
  59         '';
  60       };
  61     };
  62
  63   };
  64
  65   config = mkIf cfg.enable {
  66
  67     systemd.services.varnish = {
  68       description = "Varnish";
  69       wantedBy = [ "multi-user.target" ];
  70       after = [ "network.target" ];
  71       preStart = mkIf (!(lib.hasPrefix "/run/" cfg.stateDir)) ''
  72         mkdir -p ${cfg.stateDir}
  73         chown -R varnish:varnish ${cfg.stateDir}
  74       '';
  75       postStop = mkIf (!(lib.hasPrefix "/run/" cfg.stateDir)) ''
  76         rm -rf ${cfg.stateDir}
  77       '';
  78       serviceConfig = {
  79         Type = "simple";
  80         PermissionsStartOnly = true;
  81         ExecStart = "${cfg.package}/sbin/varnishd -a ${cfg.http_address} -n ${cfg.stateDir} -F ${cfg.extraCommandLine} ${commandLine}";
  82         Restart = "always";
  83         RestartSec = "5s";
  84         User = "varnish";
  85         Group = "varnish";
  86         RuntimeDirectory = mkIf (lib.hasPrefix "/run/" cfg.stateDir) (lib.removePrefix "/run/" cfg.stateDir);
  87         AmbientCapabilities = "cap_net_bind_service";
  88         NoNewPrivileges = true;
  89         LimitNOFILE = 131072;
  90       };
  91     };
  92
  93     environment.systemPackages = [ cfg.package ];
  94
  95     # check .vcl syntax at compile time (e.g. before nixops deployment)
  96     system.checks = mkIf cfg.enableConfigCheck [
  97       (pkgs.runCommand "check-varnish-syntax" {} ''
  98         ${cfg.package}/bin/varnishd -C ${commandLine} 2> $out || (cat $out; exit 1)
  99       '')
 100     ];
 101
 102     users.users.varnish = {
 103       group = "varnish";
 104       uid = config.ids.uids.varnish;
 105     };
 106
 107     users.groups.varnish.gid = config.ids.uids.varnish;
 108   };
 109 }