nixos/modules/system/boot/systemd/shutdown.nix

   1 {
   2   config,
   3   lib,
   4   utils,
   5   pkgs,
   6   ...
   7 }:
   8 let
   9
  10   cfg = config.systemd.shutdownRamfs;
  11
  12   ramfsContents = pkgs.writeText "shutdown-ramfs-contents.json" (builtins.toJSON cfg.storePaths);
  13
  14 in
  15 {
  16   options.systemd.shutdownRamfs = {
  17     enable = lib.mkEnableOption "pivoting back to an initramfs for shutdown" // {
  18       default = true;
  19     };
  20     contents = lib.mkOption {
  21       description = "Set of files that have to be linked into the shutdown ramfs";
  22       example = lib.literalExpression ''
  23         {
  24           "/lib/systemd/system-shutdown/zpool-sync-shutdown".source = writeShellScript "zpool" "exec ''${zfs}/bin/zpool sync"
  25         }
  26       '';
  27       type = utils.systemdUtils.types.initrdContents;
  28     };
  29
  30     storePaths = lib.mkOption {
  31       description = ''
  32         Store paths to copy into the shutdown ramfs as well.
  33       '';
  34       type = utils.systemdUtils.types.initrdStorePath;
  35       default = [ ];
  36     };
  37   };
  38
  39   config = lib.mkIf cfg.enable {
  40     systemd.shutdownRamfs.contents = {
  41       "/shutdown".source = "${config.systemd.package}/lib/systemd/systemd-shutdown";
  42       "/etc/initrd-release".source = config.environment.etc.os-release.source;
  43       "/etc/os-release".source = config.environment.etc.os-release.source;
  44     };
  45     systemd.shutdownRamfs.storePaths = [
  46       pkgs.runtimeShell
  47       "${pkgs.coreutils}/bin"
  48     ] ++ map (c: builtins.removeAttrs c [ "text" ]) (builtins.attrValues cfg.contents);
  49
  50     systemd.mounts = [
  51       {
  52         what = "tmpfs";
  53         where = "/run/initramfs";
  54         type = "tmpfs";
  55       }
  56     ];
  57
  58     systemd.services.generate-shutdown-ramfs = {
  59       description = "Generate shutdown ramfs";
  60       wantedBy = [ "shutdown.target" ];
  61       before = [ "shutdown.target" ];
  62       unitConfig = {
  63         DefaultDependencies = false;
  64         RequiresMountsFor = "/run/initramfs";
  65         ConditionFileIsExecutable = [
  66           "!/run/initramfs/shutdown"
  67         ];
  68       };
  69
  70       serviceConfig = {
  71         Type = "oneshot";
  72         ProtectSystem = "strict";
  73         ReadWritePaths = "/run/initramfs";
  74         ExecStart = "${pkgs.makeInitrdNGTool}/bin/make-initrd-ng ${ramfsContents} /run/initramfs";
  75       };
  76     };
  77   };
  78 }