nixos/tests/guix/publish.nix

   1 # Testing out the substitute server with two machines in a local network. As a
   2 # bonus, we'll also test a feature of the substitute server being able to
   3 # advertise its service to the local network with Avahi.
   4
   5 import ../make-test-python.nix (
   6   { pkgs, lib, ... }:
   7   let
   8     publishPort = 8181;
   9     inherit (builtins) toString;
  10   in
  11   {
  12     name = "guix-publish";
  13
  14     meta.maintainers = with lib.maintainers; [ foo-dogsquared ];
  15
  16     nodes =
  17       let
  18         commonConfig =
  19           { config, ... }:
  20           {
  21             # We'll be using '--advertise' flag with the
  22             # substitute server which requires Avahi.
  23             services.avahi = {
  24               enable = true;
  25               nssmdns4 = true;
  26               publish = {
  27                 enable = true;
  28                 userServices = true;
  29               };
  30             };
  31           };
  32       in
  33       {
  34         server =
  35           {
  36             config,
  37             lib,
  38             pkgs,
  39             ...
  40           }:
  41           {
  42             imports = [ commonConfig ];
  43
  44             services.guix = {
  45               enable = true;
  46               publish = {
  47                 enable = true;
  48                 port = publishPort;
  49
  50                 generateKeyPair = true;
  51                 extraArgs = [ "--advertise" ];
  52               };
  53             };
  54
  55             networking.firewall.allowedTCPPorts = [ publishPort ];
  56           };
  57
  58         client =
  59           {
  60             config,
  61             lib,
  62             pkgs,
  63             ...
  64           }:
  65           {
  66             imports = [ commonConfig ];
  67
  68             services.guix = {
  69               enable = true;
  70
  71               # Force to only get all substitutes from the local server. We don't
  72               # have anything in the Guix store directory and we cannot get
  73               # anything from the official substitute servers anyways.
  74               substituters.urls = [ "http://server.local:${toString publishPort}" ];
  75
  76               extraArgs = [
  77                 # Enable autodiscovery of the substitute servers in the local
  78                 # network. This machine shouldn't need to import the signing key from
  79                 # the substitute server since it is automatically done anyways.
  80                 "--discover=yes"
  81               ];
  82             };
  83           };
  84       };
  85
  86     testScript = ''
  87       import pathlib
  88
  89       start_all()
  90
  91       scripts_dir = pathlib.Path("/etc/guix/scripts")
  92
  93       for machine in machines:
  94         machine.wait_for_unit("multi-user.target")
  95         machine.wait_for_unit("guix-daemon.service")
  96         machine.wait_for_unit("avahi-daemon.service")
  97
  98       server.wait_for_unit("guix-publish.service")
  99       server.wait_for_open_port(${toString publishPort})
 100       server.succeed("curl http://localhost:${toString publishPort}/")
 101
 102       # Now it's the client turn to make use of it.
 103       substitute_server = "http://server.local:${toString publishPort}"
 104       client.systemctl("start network-online.target")
 105       client.wait_for_unit("network-online.target")
 106       response = client.succeed(f"curl {substitute_server}")
 107       assert "Guix Substitute Server" in response
 108
 109       # Authorizing the server to be used as a substitute server.
 110       client.succeed(f"curl -O {substitute_server}/signing-key.pub")
 111       client.succeed("guix archive --authorize < ./signing-key.pub")
 112
 113       # Since we're using the substitute server with the `--advertise` flag, we
 114       # might as well check it.
 115       client.succeed("avahi-browse --resolve --terminate _guix_publish._tcp | grep '_guix_publish._tcp'")
 116     '';
 117   }
 118 )