nixos/tests/nextcloud/with-objectstore.nix

   1 {
   2   name,
   3   pkgs,
   4   testBase,
   5   system,
   6   ...
   7 }:
   8
   9 with import ../../lib/testing-python.nix { inherit system pkgs; };
  10 runTest (
  11   { config, lib, ... }:
  12   let
  13     accessKey = "BKIKJAA5BMMU2RHO6IBB";
  14     secretKey = "V7f1CwQqAcwo80UEIJEjc5gVQUSSx5ohQ9GSrr12";
  15
  16     rootCredentialsFile = pkgs.writeText "minio-credentials-full" ''
  17       MINIO_ROOT_USER=${accessKey}
  18       MINIO_ROOT_PASSWORD=${secretKey}
  19     '';
  20   in
  21   {
  22     inherit name;
  23     meta = with pkgs.lib.maintainers; {
  24       maintainers = [
  25         onny
  26         ma27
  27       ];
  28     };
  29
  30     imports = [ testBase ];
  31
  32     nodes = {
  33       nextcloud =
  34         { config, pkgs, ... }:
  35         {
  36           networking.firewall.allowedTCPPorts = [ 9000 ];
  37           environment.systemPackages = [ pkgs.minio-client ];
  38
  39           services.nextcloud.config.objectstore.s3 = {
  40             enable = true;
  41             bucket = "nextcloud";
  42             autocreate = true;
  43             key = accessKey;
  44             secretFile = "${pkgs.writeText "secretKey" secretKey}";
  45             hostname = "nextcloud";
  46             useSsl = false;
  47             port = 9000;
  48             usePathStyle = true;
  49             region = "us-east-1";
  50           };
  51
  52           services.minio = {
  53             enable = true;
  54             listenAddress = "0.0.0.0:9000";
  55             consoleAddress = "0.0.0.0:9001";
  56             inherit rootCredentialsFile;
  57           };
  58         };
  59     };
  60
  61     test-helpers.init = ''
  62       nextcloud.wait_for_open_port(9000)
  63     '';
  64
  65     test-helpers.extraTests =
  66       { nodes, ... }:
  67       ''
  68         with subtest("File is not on the filesystem"):
  69             nextcloud.succeed("test ! -e ${nodes.nextcloud.services.nextcloud.home}/data/root/files/test-shared-file")
  70
  71         with subtest("Check if file is in S3"):
  72             nextcloud.succeed(
  73                 "mc config host add minio http://localhost:9000 ${accessKey} ${secretKey} --api s3v4"
  74             )
  75             files = nextcloud.succeed('mc ls minio/nextcloud|sort').strip().split('\n')
  76
  77             # Cannot assert an exact number here, nc27 writes more stuff initially into S3.
  78             # For now let's assume it's always the most recently added file.
  79             assert len(files) > 0, f"""
  80               Expected to have at least one object in minio/nextcloud. But `mc ls` gave output:
  81
  82               '{files}'
  83             """
  84
  85             import re
  86             ptrn = re.compile("^\[[A-Z0-9 :-]+\] +(?P<details>[A-Za-z0-9 :]+)$")
  87             match = ptrn.match(files[-1].strip())
  88             assert match, "Cannot match mc client output!"
  89             size, type_, file = tuple(match.group('details').split(' '))
  90
  91             assert size == "3B", f"""
  92               Expected size of uploaded file to be 3 bytes, got {size}
  93             """
  94
  95             assert type_ == 'STANDARD', f"""
  96               Expected type of bucket entry to be a file, i.e. 'STANDARD'. Got {type_}
  97             """
  98
  99             assert file.startswith('urn:oid'), """
 100               Expected filename to start with 'urn:oid', instead got '{file}.
 101             """
 102
 103         with subtest("Test download from S3"):
 104             client.succeed(
 105                 "env AWS_ACCESS_KEY_ID=${accessKey} AWS_SECRET_ACCESS_KEY=${secretKey} "
 106                 + f"${lib.getExe pkgs.awscli2} s3 cp s3://nextcloud/{file} test --endpoint-url http://nextcloud:9000 "
 107                 + "--region us-east-1"
 108             )
 109
 110             client.succeed("test hi = $(cat test)")
 111       '';
 112   }
 113 )