pkgs/applications/audio/munt/mt32emu-smf2wav.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   cmake,
   6   glib,
   7   libmt32emu,
   8   pkg-config,
   9 }:
  10
  11 let
  12   char2underscore = char: str: lib.replaceStrings [ char ] [ "_" ] str;
  13 in
  14 stdenv.mkDerivation rec {
  15   pname = "mt32emu-smf2wav";
  16   version = "1.9.0";
  17
  18   src = fetchFromGitHub {
  19     owner = "munt";
  20     repo = "munt";
  21     rev = "${char2underscore "-" pname}_${char2underscore "." version}";
  22     sha256 = "sha256-XGds9lDfSiY0D8RhYG4TGyjYEVvVYuAfNSv9+VxiJEs=";
  23   };
  24
  25   postPatch = ''
  26     sed -i -e '/add_subdirectory(mt32emu)/d' CMakeLists.txt
  27   '';
  28
  29   dontFixCmake = true;
  30
  31   nativeBuildInputs = [
  32     cmake
  33     pkg-config
  34   ];
  35
  36   buildInputs = [
  37     libmt32emu
  38     glib
  39   ];
  40
  41   cmakeFlags = [
  42     "-Dmunt_WITH_MT32EMU_QT=OFF"
  43     "-Dmunt_WITH_MT32EMU_SMF2WAV=ON"
  44   ];
  45
  46   meta = with lib; {
  47     homepage = "https://munt.sourceforge.net/";
  48     description = "Produces a WAVE file from a Standard MIDI file (SMF)";
  49     mainProgram = "mt32emu-smf2wav";
  50     license = with licenses; [ gpl3Plus ];
  51     maintainers = with maintainers; [ OPNA2608 ];
  52     platforms = platforms.all;
  53   };
  54 }