pkgs/applications/editors/vscode/extensions/chenglou92.rescript-vscode/default.nix

   1 {
   2   lib,
   3   stdenv,
   4   vscode-utils,
   5   callPackage,
   6 }:
   7 let
   8   version = "1.60.0";
   9   rescript-editor-analysis = callPackage ./rescript-editor-analysis.nix { inherit version; };
  10   arch =
  11     if stdenv.hostPlatform.isLinux then
  12       "linux"
  13     else if stdenv.hostPlatform.isDarwin then
  14       "darwin"
  15     else
  16       throw "Unsupported system: ${stdenv.system}";
  17   analysisDir = "server/analysis_binaries/${arch}";
  18 in
  19 vscode-utils.buildVscodeMarketplaceExtension rec {
  20   mktplcRef = {
  21     name = "rescript-vscode";
  22     publisher = "chenglou92";
  23     inherit version;
  24     hash = "sha256-1jdjSxho7TRADAxs4ccLw7Ea430f+L5aBlLDlUwvXHk=";
  25   };
  26   postPatch = ''
  27     rm -r ${analysisDir}
  28     ln -s ${rescript-editor-analysis}/bin ${analysisDir}
  29   '';
  30
  31   meta = {
  32     description = "Official VSCode plugin for ReScript";
  33     homepage = "https://github.com/rescript-lang/rescript-vscode";
  34     maintainers = [
  35       lib.maintainers.dlip
  36       lib.maintainers.jayesh-bhoot
  37     ];
  38     license = lib.licenses.mit;
  39   };
  40 }