pkgs/applications/graphics/nufraw/default.nix

   1 { lib
   2 , stdenv
   3 , fetchurl
   4 , fetchpatch
   5
   6 , autoreconfHook
   7 , bzip2
   8 , cfitsio
   9 , exiv2
  10 , gettext
  11 , gtk2
  12 , gtkimageview
  13 , lcms2
  14 , lensfun
  15 , libjpeg
  16 , libtiff
  17 , perl
  18 , pkg-config
  19 , zlib
  20
  21 , addThumbnailer ? false
  22 }:
  23
  24 stdenv.mkDerivation rec {
  25   pname = "nufraw";
  26   version = "0.43-3";
  27
  28   src = fetchurl {
  29     url = "mirror://sourceforge/nufraw/nufraw-${version}.tar.gz";
  30     sha256 = "0b63qvw9r8kaqw36bk3a9zwxc41h8fr6498indkw4glrj0awqz9c";
  31   };
  32
  33   nativeBuildInputs = [ autoreconfHook gettext perl pkg-config ];
  34
  35   buildInputs = [
  36     bzip2
  37     cfitsio
  38     exiv2
  39     gtk2
  40     gtkimageview
  41     lcms2
  42     lensfun
  43     libjpeg
  44     libtiff
  45     zlib
  46   ];
  47
  48   configureFlags = [
  49     "--enable-contrast"
  50     "--enable-dst-correction"
  51   ];
  52
  53   env.NIX_CFLAGS_COMPILE = "-Wno-narrowing";
  54
  55   postInstall = lib.optionalString addThumbnailer ''
  56     mkdir -p $out/share/thumbnailers
  57     substituteAll ${./nufraw.thumbnailer} $out/share/thumbnailers/${pname}.thumbnailer
  58   '';
  59
  60   patches = [
  61     # Fixes an upstream issue where headers with templates were included in an extern-C scope
  62     # which caused the build to fail
  63     (fetchpatch {
  64       name = "0001-nufraw-glib-2.70.patch";
  65       url = "https://gitlab.archlinux.org/archlinux/packaging/packages/gimp-nufraw/-/raw/3405bc864752dbd04f2d182a21b4108d6cc3aa95/0001-nufraw-glib-2.70.patch";
  66       hash = "sha256-XgzgjikWTcqymHa7bKmruNZaeb2/lpN19HXoRUt5rTk=";
  67     })
  68   ] ++ lib.optionals (lib.versionAtLeast exiv2.version "0.28") [
  69     (fetchpatch {
  70       name = "0002-exiv2-error.patch";
  71       url = "https://gitlab.archlinux.org/archlinux/packaging/packages/gimp-nufraw/-/raw/3405bc864752dbd04f2d182a21b4108d6cc3aa95/0002-exiv2-error.patch";
  72       hash = "sha256-40/Wwk1sWiaIWp077EYgP8jFO4k1cvf30heRDMYJw3M=";
  73     })
  74   ];
  75
  76   meta = with lib; {
  77     homepage = "https://nufraw.sourceforge.io/";
  78     description = "Utility to read and manipulate raw images from digital cameras";
  79     longDescription =
  80       ''
  81         A new version of the popular raw digital images manipulator ufraw.
  82         Forks from the version 0.23 of ufraw (that's why the first nufraw version is the 0.24).
  83         Nufraw offers the same features (gimp plugin, batch, ecc) and the same quality of
  84         ufraw in a brand new improved user interface.
  85       '';
  86     license = licenses.gpl2Plus;
  87     maintainers = with maintainers; [ asbachb ];
  88     platforms = platforms.linux;
  89   };
  90 }