pkgs/applications/kde/k3b.nix

   1 { mkDerivation, lib
   2 , extra-cmake-modules, kdoctools, makeWrapper, shared-mime-info
   3 , libkcddb, karchive, kcmutils, kfilemetadata, knewstuff, knotifyconfig, solid, kxmlgui
   4 , flac, lame, libmad, libmpcdec, libvorbis
   5 , libsamplerate, libsndfile, taglib
   6 , cdparanoia, cdrdao, cdrtools, dvdplusrwtools, libburn, libdvdcss, libdvdread, vcdimager
   7 , ffmpeg, libmusicbrainz3, normalize, sox, transcode, kinit
   8 }:
   9
  10 mkDerivation {
  11   pname = "k3b";
  12   meta = with lib; {
  13     homepage = "https://apps.kde.org/k3b/";
  14     description = "Disk burning application";
  15     mainProgram = "k3b";
  16     license = with licenses; [ gpl2Plus ];
  17     maintainers = with maintainers; [ sander ];
  18     platforms = platforms.linux;
  19   };
  20   nativeBuildInputs = [ extra-cmake-modules kdoctools makeWrapper ];
  21   buildInputs = [
  22     # kde
  23     libkcddb karchive kcmutils kfilemetadata knewstuff knotifyconfig solid kxmlgui
  24     # formats
  25     flac lame libmad libmpcdec libvorbis
  26     # sound utilities
  27     libsamplerate libsndfile taglib
  28     # cd/dvd
  29     cdparanoia libdvdcss libdvdread
  30     # others
  31     ffmpeg libmusicbrainz3 shared-mime-info
  32   ];
  33   propagatedUserEnvPkgs = [ (lib.getBin kinit) ];
  34   postFixup =
  35     let
  36       binPath = lib.makeBinPath [
  37         cdrdao cdrtools dvdplusrwtools libburn normalize sox transcode
  38         vcdimager flac
  39       ];
  40       libraryPath = lib.makeLibraryPath [
  41         cdparanoia
  42       ];
  43     in ''
  44       wrapProgram "$out/bin/k3b"     \
  45         --prefix PATH : "${binPath}" \
  46         --prefix LD_LIBRARY_PATH : ${libraryPath}
  47     '';
  48 }