pkgs/applications/networking/instant-messengers/profanity/default.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   autoconf-archive,
   6   autoreconfHook,
   7   cmocka,
   8   curl,
   9   expat,
  10   expect,
  11   glib,
  12   glibcLocales,
  13   libstrophe,
  14   libmicrohttpd,
  15   libotr,
  16   libuuid,
  17   ncurses,
  18   openssl,
  19   pkg-config,
  20   readline,
  21   sqlite,
  22   autoAwaySupport ? true,
  23   libXScrnSaver,
  24   libX11,
  25   notifySupport ? true,
  26   libnotify,
  27   gdk-pixbuf,
  28   omemoSupport ? true,
  29   libsignal-protocol-c,
  30   libgcrypt,
  31   qrencode,
  32   pgpSupport ? true,
  33   gpgme,
  34   pythonPluginSupport ? true,
  35   python3,
  36   traySupport ? true,
  37   gtk3,
  38 }:
  39
  40 stdenv.mkDerivation rec {
  41   pname = "profanity";
  42   version = "0.14.0";
  43
  44   src = fetchFromGitHub {
  45     owner = "profanity-im";
  46     repo = "profanity";
  47     rev = version;
  48     hash = "sha256-u/mp+vtMj602LfrulA+nhLNH8K6sqKIOuPJzhZusVmE=";
  49   };
  50
  51   patches = [
  52     ./patches/packages-osx.patch
  53   ];
  54
  55   enableParallelBuilding = true;
  56
  57   nativeBuildInputs = [
  58     autoconf-archive
  59     autoreconfHook
  60     glibcLocales
  61     pkg-config
  62   ];
  63
  64   buildInputs =
  65     [
  66       cmocka
  67       curl
  68       expat
  69       expect
  70       glib
  71       libstrophe
  72       libmicrohttpd
  73       libotr
  74       libuuid
  75       ncurses
  76       openssl
  77       readline
  78       sqlite
  79     ]
  80     ++ lib.optionals autoAwaySupport [
  81       libXScrnSaver
  82       libX11
  83     ]
  84     ++ lib.optionals notifySupport [
  85       libnotify
  86       gdk-pixbuf
  87     ]
  88     ++ lib.optionals omemoSupport [
  89       libsignal-protocol-c
  90       libgcrypt
  91       qrencode
  92     ]
  93     ++ lib.optionals pgpSupport [ gpgme ]
  94     ++ lib.optionals pythonPluginSupport [ python3 ]
  95     ++ lib.optionals traySupport [ gtk3 ];
  96
  97   # Enable feature flags, so that build fail if libs are missing
  98   configureFlags =
  99     [
 100       "--enable-c-plugins"
 101       "--enable-otr"
 102     ]
 103     ++ lib.optionals notifySupport [ "--enable-notifications" ]
 104     ++ lib.optionals traySupport [ "--enable-icons-and-clipboard" ]
 105     ++ lib.optionals pgpSupport [ "--enable-pgp" ]
 106     ++ lib.optionals pythonPluginSupport [ "--enable-python-plugins" ]
 107     ++ lib.optionals omemoSupport [ "--enable-omemo" ];
 108
 109   preAutoreconf = ''
 110     mkdir m4
 111   '';
 112
 113   doCheck = true;
 114
 115   LC_ALL = "en_US.utf8";
 116
 117   meta = with lib; {
 118     homepage = "http://www.profanity.im/";
 119     description = "Console based XMPP client";
 120     mainProgram = "profanity";
 121     longDescription = ''
 122       Profanity is a console based XMPP client written in C using ncurses and
 123       libstrophe, inspired by Irssi.
 124     '';
 125     license = licenses.gpl3Plus;
 126     maintainers = [ maintainers.devhell ];
 127     platforms = platforms.unix;
 128   };
 129 }