pkgs/applications/networking/znc/modules.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   znc,
   6 }:
   7
   8 let
   9   zncDerivation =
  10     a@{
  11       pname,
  12       src,
  13       module_name,
  14       buildPhase ? "${znc}/bin/znc-buildmod ${module_name}.cpp",
  15       installPhase ? "install -D ${module_name}.so $out/lib/znc/${module_name}.so",
  16       ...
  17     }:
  18     stdenv.mkDerivation (
  19       a
  20       // {
  21         inherit buildPhase;
  22         inherit installPhase;
  23
  24         buildInputs = znc.buildInputs;
  25
  26         meta = a.meta // {
  27           platforms = lib.platforms.unix;
  28         };
  29         passthru.module_name = module_name;
  30       }
  31     );
  32
  33 in
  34 {
  35
  36   backlog = zncDerivation rec {
  37     pname = "znc-backlog";
  38     version = "unstable-2017-06-13";
  39     module_name = "backlog";
  40
  41     src = fetchFromGitHub {
  42       owner = "FruitieX";
  43       repo = "znc-backlog";
  44       rev = "42e8f439808882d2dae60f2a161eabead14e4b0d";
  45       sha256 = "1k7ifpqqzzf2j7w795q4mx1nvmics2higzjqr3mid3lp43sqg5s6";
  46     };
  47
  48     meta = with lib; {
  49       description = "Request backlog for IRC channels";
  50       homepage = "https://github.com/fruitiex/znc-backlog/";
  51       license = licenses.asl20;
  52       maintainers = [ ];
  53     };
  54   };
  55
  56   clientbuffer = zncDerivation rec {
  57     pname = "znc-clientbuffer";
  58     version = "unstable-2021-05-30";
  59     module_name = "clientbuffer";
  60
  61     src = fetchFromGitHub {
  62       owner = "CyberShadow";
  63       repo = "znc-clientbuffer";
  64       rev = "9a7465b413b53408f5d7af86e84b1d08efb6bec0";
  65       sha256 = "0a3f4j6s5j7p53y42zrgpqyl2zm0jxb69lp24j6mni3licigh254";
  66     };
  67
  68     meta = with lib; {
  69       description = "ZNC module for client specific buffers";
  70       homepage = "https://github.com/CyberShadow/znc-clientbuffer";
  71       license = licenses.asl20;
  72       maintainers = with maintainers; [
  73         hrdinka
  74         szlend
  75         cybershadow
  76       ];
  77     };
  78   };
  79
  80   clientaway = zncDerivation rec {
  81     pname = "znc-clientaway";
  82     version = "unstable-2017-04-28";
  83     module_name = "clientaway";
  84
  85     src = fetchFromGitHub {
  86       owner = "kylef";
  87       repo = "znc-contrib";
  88       rev = "f6724a4a3b16b050088adde0cbeed74f189e5044";
  89       sha256 = "0ikd3dzjjlr0gs0ikqfk50msm6mij99ln2rjzqavh58iwzr7n5r8";
  90     };
  91
  92     meta = with lib; {
  93       description = "ZNC clientaway module";
  94       homepage = "https://github.com/kylef/znc-contrib";
  95       license = licenses.gpl2;
  96       maintainers = [ ];
  97     };
  98   };
  99
 100   fish = zncDerivation rec {
 101     pname = "znc-fish";
 102     version = "unstable-2017-06-26";
 103     module_name = "fish";
 104
 105     src = fetchFromGitHub {
 106       # this fork works with ZNC 1.7
 107       owner = "oilslump";
 108       repo = "znc-fish";
 109       rev = "7d91467dbb195f7b591567911210523c6087662e";
 110       sha256 = "1ky5xg17k5f393whrv5iv8zsmdvdyk2f7z5qdsmxcwy3pdxy6vsm";
 111     };
 112
 113     meta = {
 114       description = "ZNC FiSH module";
 115       homepage = "https://github.com/dctrwatson/znc-fish";
 116       maintainers = [ lib.maintainers.offline ];
 117     };
 118   };
 119
 120   ignore = zncDerivation rec {
 121     pname = "znc-ignore";
 122     version = "unstable-2017-04-28";
 123     module_name = "ignore";
 124
 125     src = fetchFromGitHub {
 126       owner = "kylef";
 127       repo = "znc-contrib";
 128       rev = "f6724a4a3b16b050088adde0cbeed74f189e5044";
 129       sha256 = "0ikd3dzjjlr0gs0ikqfk50msm6mij99ln2rjzqavh58iwzr7n5r8";
 130     };
 131
 132     meta = with lib; {
 133       description = "ZNC ignore module";
 134       homepage = "https://github.com/kylef/znc-contrib";
 135       license = licenses.gpl2;
 136       maintainers = [ ];
 137     };
 138   };
 139
 140   palaver = zncDerivation rec {
 141     pname = "znc-palaver";
 142     version = "1.2.2";
 143     module_name = "palaver";
 144
 145     src = fetchFromGitHub {
 146       owner = "cocodelabs";
 147       repo = "znc-palaver";
 148       rev = version;
 149       hash = "sha256-8W3uF1PrLQiEZm7JaFrpqmJLSFioa4F4qlM1J6Zua8U=";
 150     };
 151
 152     meta = with lib; {
 153       description = "Palaver ZNC module";
 154       homepage = "https://github.com/cocodelabs/znc-palaver";
 155       license = licenses.mit;
 156       maintainers = with maintainers; [ szlend ];
 157     };
 158   };
 159
 160   playback = zncDerivation rec {
 161     pname = "znc-playback";
 162     version = "unstable-2015-08-04";
 163     module_name = "playback";
 164
 165     src = fetchFromGitHub {
 166       owner = "jpnurmi";
 167       repo = "znc-playback";
 168       rev = "8691abf75becc1f3d7b5bb5ad68dad17cd21863b";
 169       sha256 = "0mgfajljy035051b2sx70i8xrb51zw9q2z64kf85zw1lynihzyh4";
 170     };
 171
 172     meta = with lib; {
 173       description = "Advanced playback module for ZNC";
 174       homepage = "https://github.com/jpnurmi/znc-playback";
 175       license = licenses.asl20;
 176       maintainers = with maintainers; [ hrdinka ];
 177     };
 178   };
 179
 180   privmsg = zncDerivation rec {
 181     pname = "znc-privmsg";
 182     version = "unstable-2015-02-22";
 183     module_name = "privmsg";
 184
 185     src = fetchFromGitHub {
 186       owner = "kylef";
 187       repo = "znc-contrib";
 188       rev = "9f1f98db56cbbea96d83e6628f657e0d62cd9517";
 189       sha256 = "0n82z87gdxxragcaixjc80z8bw4bmfwbk0jrf9zs8kk42phlkkc2";
 190     };
 191
 192     meta = {
 193       description = "ZNC privmsg module";
 194       homepage = "https://github.com/kylef/znc-contrib";
 195     };
 196   };
 197
 198   push = zncDerivation rec {
 199     pname = "znc-push";
 200     version = "unstable-2016-10-12";
 201     module_name = "push";
 202
 203     src = fetchFromGitHub {
 204       owner = "jreese";
 205       repo = "znc-push";
 206       rev = "cf08b9e0f483f03c28d72dd78df932cbef141f10";
 207       sha256 = "0xpwjw8csyrg736g1jc1n8d6804x6kbdkrvldzhk9ldj4iwqz7ay";
 208     };
 209
 210     meta = {
 211       description = "Push notification service module for ZNC";
 212       homepage = "https://github.com/jreese/znc-push";
 213       license = lib.licenses.mit;
 214       maintainers = with lib.maintainers; [
 215         offline
 216         schneefux
 217       ];
 218     };
 219   };
 220
 221 }