pkgs/applications/science/math/lp_solve/default.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchurl,
   5   cctools,
   6   fixDarwinDylibNames,
   7   autoSignDarwinBinariesHook,
   8 }:
   9
  10 stdenv.mkDerivation rec {
  11   pname = "lp_solve";
  12   version = "5.5.2.11";
  13
  14   src = fetchurl {
  15     url = "mirror://sourceforge/project/lpsolve/lpsolve/${version}/lp_solve_${version}_source.tar.gz";
  16     sha256 = "sha256-bUq/9cxqqpM66ObBeiJt8PwLZxxDj2lxXUHQn+gfkC8=";
  17   };
  18
  19   nativeBuildInputs =
  20     lib.optionals stdenv.hostPlatform.isDarwin [
  21       cctools
  22       fixDarwinDylibNames
  23     ]
  24     ++ lib.optionals (stdenv.hostPlatform.isDarwin && stdenv.hostPlatform.isAarch64) [
  25       autoSignDarwinBinariesHook
  26     ];
  27
  28   env =
  29     {
  30       NIX_CFLAGS_COMPILE = "-Wno-error=implicit-int";
  31     }
  32     // lib.optionalAttrs (stdenv.hostPlatform.isDarwin && stdenv.hostPlatform.isx86_64) {
  33       NIX_LDFLAGS = "-headerpad_max_install_names";
  34     };
  35
  36   dontConfigure = true;
  37
  38   buildPhase =
  39     let
  40       ccc = if stdenv.hostPlatform.isDarwin then "ccc.osx" else "ccc";
  41     in
  42     ''
  43       runHook preBuild
  44
  45       (cd lpsolve55 && bash -x -e ${ccc})
  46       (cd lp_solve  && bash -x -e ${ccc})
  47
  48       runHook postBuild
  49     '';
  50
  51   installPhase = ''
  52     runHook preInstall
  53
  54     install -d -m755 $out/bin $out/lib $out/include/lpsolve
  55     install -m755 lp_solve/bin/*/lp_solve -t $out/bin
  56     install -m644 lpsolve55/bin/*/liblpsolve* -t $out/lib
  57     install -m644 lp_*.h -t $out/include/lpsolve
  58
  59     rm $out/lib/liblpsolve*.a
  60     rm $out/include/lpsolve/lp_solveDLL.h  # A Windows header
  61
  62     runHook postInstall
  63   '';
  64
  65   meta = with lib; {
  66     description = "Mixed Integer Linear Programming (MILP) solver";
  67     mainProgram = "lp_solve";
  68     homepage = "https://lpsolve.sourceforge.net";
  69     license = licenses.gpl2Plus;
  70     maintainers = with maintainers; [ smironov ];
  71     platforms = platforms.unix;
  72   };
  73 }