pkgs/applications/science/math/qalculate-qt/default.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   intltool,
   6   pkg-config,
   7   qmake,
   8   wrapQtAppsHook,
   9   libqalculate,
  10   qtbase,
  11   qttools,
  12   qtsvg,
  13   qtwayland,
  14 }:
  15
  16 stdenv.mkDerivation (finalAttrs: {
  17   pname = "qalculate-qt";
  18   version = "5.4.0";
  19
  20   src = fetchFromGitHub {
  21     owner = "qalculate";
  22     repo = "qalculate-qt";
  23     rev = "v${finalAttrs.version}";
  24     hash = "sha256-Tpb/ZN5p3JfPug9NpBHguOi6Okek+g87orD4ISkV+ac=";
  25   };
  26
  27   nativeBuildInputs = [
  28     qmake
  29     intltool
  30     pkg-config
  31     qttools
  32     wrapQtAppsHook
  33   ];
  34   buildInputs = [
  35     libqalculate
  36     qtbase
  37     qtsvg
  38   ] ++ lib.optionals stdenv.hostPlatform.isLinux [ qtwayland ];
  39
  40   postPatch = ''
  41     substituteInPlace qalculate-qt.pro\
  42       --replace "LRELEASE" "${qttools.dev}/bin/lrelease"
  43   '';
  44
  45   postInstall = lib.optionalString stdenv.hostPlatform.isDarwin ''
  46     mkdir -p $out/Applications
  47     mv $out/bin/qalculate-qt.app $out/Applications
  48     makeWrapper $out/{Applications/qalculate-qt.app/Contents/MacOS,bin}/qalculate-qt
  49   '';
  50
  51   meta = with lib; {
  52     description = "Ultimate desktop calculator";
  53     homepage = "http://qalculate.github.io";
  54     maintainers = with maintainers; [ _4825764518 ];
  55     license = licenses.gpl2Plus;
  56     mainProgram = "qalculate-qt";
  57     platforms = platforms.unix;
  58   };
  59 })