pkgs/applications/science/programming/fdr/default.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchurl,
   5   qtbase,
   6   qtx11extras,
   7   ncurses5,
   8   xorg,
   9   zlib,
  10   python27Packages,
  11 }:
  12 stdenv.mkDerivation {
  13   pname = "fdr";
  14   version = "4.2.7";
  15   src = fetchurl {
  16     url = "https://dl.cocotec.io/fdr/fdr-3814-linux-x86_64.tar.gz";
  17     sha256 = "0cajz1gz4slq9nfhm8dqdgxl0kc950838n0lrf8jw4vl54gv6chh";
  18   };
  19
  20   libPath = lib.makeLibraryPath [
  21     stdenv.cc.cc
  22     python27Packages.python
  23     qtbase
  24     qtx11extras
  25     ncurses5
  26     xorg.libX11
  27     xorg.libXft
  28     zlib
  29   ];
  30
  31   dontConfigure = true;
  32   installPhase = ''
  33     mkdir -p "$out"
  34
  35     # shipped Qt is buggy
  36     rm lib/libQt*
  37     rm -r lib/qt_plugins
  38
  39     cp -r * "$out"
  40     ln -s ${ncurses5.out}/lib/libtinfo.so.5 $out/lib/libtinfo.so.5
  41     ln -s ${qtbase.bin}/${qtbase.qtPluginPrefix} $out/lib/qt_plugins
  42     ln -s ${zlib.out}/lib/libz.so.1 $out/lib/libz.so.1
  43
  44     for b in fdr4 _fdr4 refines _refines cspmprofiler cspmexplorerprof
  45     do
  46       patchelf --set-interpreter $(cat $NIX_CC/nix-support/dynamic-linker) \
  47         --set-rpath "$libPath:$out/lib" \
  48         "$out/bin/$b"
  49     done
  50
  51     for l in corei7/librefines.so \
  52       libcspm_process_compiler.so \
  53       libcsp_operators.so \
  54       _fdr.so \
  55       libfdr.so \
  56       libfdr_java.so \
  57       libprocess_compiler.so \
  58       librefines_gui.so \
  59       librefines_licensing.so  \
  60       libboost_date_time.so.1.60.0 \
  61       libboost_filesystem.so.1.60.0 \
  62       libboost_iostreams.so.1.60.0 \
  63       libboost_program_options.so.1.60.0 \
  64       libboost_serialization.so.1.60.0 \
  65       libboost_system.so.1.60.0
  66     do
  67       patchelf --set-rpath "$libPath:$out/lib" \
  68         "$out/lib/$l"
  69     done
  70   '';
  71
  72   meta = with lib; {
  73     homepage = "https://cocotec.io/fdr/";
  74     description = "CSP refinement checker";
  75     license = licenses.unfreeRedistributable;
  76     sourceProvenance = with sourceTypes; [ binaryNativeCode ];
  77     platforms = platforms.linux;
  78     maintainers = with maintainers; [ nickhu ];
  79   };
  80 }