pkgs/applications/terminal-emulators/cool-retro-term/default.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , mkDerivation
   5 , qtbase
   6 , qmltermwidget
   7 , qtquickcontrols2
   8 , qtgraphicaleffects
   9 , qmake
  10 , nixosTests
  11 }:
  12
  13 mkDerivation rec {
  14   version = "1.2.0";
  15   pname = "cool-retro-term";
  16
  17   src = fetchFromGitHub {
  18     owner = "Swordfish90";
  19     repo = "cool-retro-term";
  20     rev = "refs/tags/${version}";
  21     hash = "sha256-PewHLVmo+RTBHIQ/y2FBkgXsIvujYd7u56JdFC10B4c=";
  22   };
  23
  24   patchPhase = ''
  25     sed -i -e '/qmltermwidget/d' cool-retro-term.pro
  26   '';
  27
  28   buildInputs = [
  29     qtbase
  30     qmltermwidget
  31     qtquickcontrols2
  32     qtgraphicaleffects
  33   ];
  34
  35   nativeBuildInputs = [ qmake ];
  36
  37   installFlags = [ "INSTALL_ROOT=$(out)" ];
  38
  39   preFixup = ''
  40     mv $out/usr/share $out/share
  41     mv $out/usr/bin $out/bin
  42     rmdir $out/usr
  43   '' + lib.optionalString stdenv.hostPlatform.isDarwin ''
  44     ln -s $out/bin/cool-retro-term.app/Contents/MacOS/cool-retro-term $out/bin/cool-retro-term
  45   '';
  46
  47   passthru.tests.test = nixosTests.terminal-emulators.cool-retro-term;
  48
  49   meta = {
  50     description = "Terminal emulator which mimics the old cathode display";
  51     longDescription = ''
  52       cool-retro-term is a terminal emulator which tries to mimic the look and
  53       feel of the old cathode tube screens. It has been designed to be
  54       eye-candy, customizable, and reasonably lightweight.
  55     '';
  56     homepage = "https://github.com/Swordfish90/cool-retro-term";
  57     license = lib.licenses.gpl3Plus;
  58     platforms = with lib.platforms; linux ++ darwin;
  59     maintainers = [ ];
  60     mainProgram = "cool-retro-term";
  61   };
  62 }