pkgs/applications/version-management/git/default.nix

   1 { fetchurl, fetchpatch, lib, stdenv, buildPackages
   2 , curl, openssl, zlib, expat, perlPackages, python3, gettext, cpio
   3 , gnugrep, gnused, gawk, coreutils # needed at runtime by git-filter-branch etc
   4 , openssh, pcre2, bash
   5 , asciidoc, texinfo, xmlto, docbook2x, docbook_xsl, docbook_xml_dtd_45
   6 , libxslt, tcl, tk, makeWrapper, libiconv, libiconvReal
   7 , svnSupport ? false, subversionClient, perlLibs, smtpPerlLibs
   8 , perlSupport ? stdenv.buildPlatform == stdenv.hostPlatform
   9 , nlsSupport ? true
  10 , osxkeychainSupport ? stdenv.hostPlatform.isDarwin
  11 , guiSupport ? false
  12 , withManual ? true
  13 , pythonSupport ? true
  14 , withpcre2 ? true
  15 , sendEmailSupport ? perlSupport
  16 , Security, CoreServices
  17 , nixosTests
  18 , withLibsecret ? false
  19 , pkg-config, glib, libsecret
  20 , gzip # needed at runtime by gitweb.cgi
  21 , withSsh ? false
  22 , sysctl
  23 , deterministic-host-uname # trick Makefile into targeting the host platform when cross-compiling
  24 , doInstallCheck ? !stdenv.hostPlatform.isDarwin  # extremely slow on darwin
  25 , tests
  26 }:
  27
  28 assert osxkeychainSupport -> stdenv.hostPlatform.isDarwin;
  29 assert sendEmailSupport -> perlSupport;
  30 assert svnSupport -> perlSupport;
  31
  32 let
  33   version = "2.47.0";
  34   svn = subversionClient.override { perlBindings = perlSupport; };
  35   gitwebPerlLibs = with perlPackages; [ CGI HTMLParser CGIFast FCGI FCGIProcManager HTMLTagCloud ];
  36 in
  37
  38 stdenv.mkDerivation (finalAttrs: {
  39   pname = "git"
  40     + lib.optionalString svnSupport "-with-svn"
  41     + lib.optionalString (!svnSupport && !guiSupport && !sendEmailSupport && !withManual && !pythonSupport && !withpcre2) "-minimal";
  42   inherit version;
  43
  44   src = fetchurl {
  45     url = "https://www.kernel.org/pub/software/scm/git/git-${version}.tar.xz";
  46     hash = "sha256-HOEU2ohwQnG0PgJ8UeBNk5n4yI6e91Qtrnrrrn2HvE4=";
  47   };
  48
  49   outputs = [ "out" ] ++ lib.optional withManual "doc";
  50   separateDebugInfo = true;
  51
  52   hardeningDisable = [ "format" ];
  53
  54   enableParallelBuilding = true;
  55
  56   patches = [
  57     ./docbook2texi.patch
  58     ./git-sh-i18n.patch
  59     ./git-send-email-honor-PATH.patch
  60     ./installCheck-path.patch
  61   ] ++ lib.optionals withSsh [
  62     ./ssh-path.patch
  63   ] ++ lib.optionals (guiSupport && stdenv.hostPlatform.isDarwin) [
  64     # Needed to workaround an issue in macOS where gitk shows a empty window
  65     # https://github.com/Homebrew/homebrew-core/issues/68798
  66     # https://github.com/git/git/pull/944
  67     (fetchpatch {
  68       name = "gitk_check_main_window_visibility_before_waiting_for_it_to_show.patch";
  69       url = "https://github.com/git/git/commit/1db62e44b7ec93b6654271ef34065b31496cd02e.patch";
  70       hash = "sha256-ntvnrYFFsJ1Ebzc6vM9/AMFLHMS1THts73PIOG5DkQo=";
  71     })
  72   ];
  73
  74   postPatch = ''
  75     # Fix references to gettext introduced by ./git-sh-i18n.patch
  76     substituteInPlace git-sh-i18n.sh \
  77         --subst-var-by gettext ${gettext}
  78
  79     # ensure we are using the correct shell when executing the test scripts
  80     patchShebangs t/*.sh
  81   '' + lib.optionalString withSsh ''
  82     for x in connect.c git-gui/lib/remote_add.tcl ; do
  83       substituteInPlace "$x" \
  84         --subst-var-by ssh "${openssh}/bin/ssh"
  85     done
  86   '';
  87
  88   nativeBuildInputs = [ deterministic-host-uname gettext perlPackages.perl makeWrapper pkg-config ]
  89     ++ lib.optionals withManual [ asciidoc texinfo xmlto docbook2x
  90          docbook_xsl docbook_xml_dtd_45 libxslt ];
  91   buildInputs = [ curl openssl zlib expat cpio (if stdenv.hostPlatform.isFreeBSD then libiconvReal else libiconv) bash ]
  92     ++ lib.optionals perlSupport [ perlPackages.perl ]
  93     ++ lib.optionals guiSupport [tcl tk]
  94     ++ lib.optionals withpcre2 [ pcre2 ]
  95     ++ lib.optionals stdenv.hostPlatform.isDarwin [ Security CoreServices ]
  96     ++ lib.optionals withLibsecret [ glib libsecret ];
  97
  98   # required to support pthread_cancel()
  99   NIX_LDFLAGS = lib.optionalString (stdenv.cc.isGNU && stdenv.hostPlatform.libc == "glibc") "-lgcc_s"
 100               + lib.optionalString (stdenv.hostPlatform.isFreeBSD) "-lthr";
 101
 102   configureFlags = [
 103     "ac_cv_prog_CURL_CONFIG=${lib.getDev curl}/bin/curl-config"
 104   ] ++ lib.optionals (stdenv.buildPlatform != stdenv.hostPlatform) [
 105     "ac_cv_fread_reads_directories=yes"
 106     "ac_cv_snprintf_returns_bogus=no"
 107     "ac_cv_iconv_omits_bom=no"
 108   ];
 109
 110   preBuild = ''
 111     makeFlagsArray+=( perllibdir=$out/$(perl -MConfig -wle 'print substr $Config{installsitelib}, 1 + length $Config{siteprefixexp}') )
 112   '';
 113
 114   makeFlags = [
 115     "prefix=\${out}"
 116   ]
 117   # Git does not allow setting a shell separately for building and run-time.
 118   # Therefore lets leave it at the default /bin/sh when cross-compiling
 119   ++ lib.optional (stdenv.buildPlatform == stdenv.hostPlatform) "SHELL_PATH=${stdenv.shell}"
 120   ++ (if perlSupport then ["PERL_PATH=${perlPackages.perl}/bin/perl"] else ["NO_PERL=1"])
 121   ++ (if pythonSupport then ["PYTHON_PATH=${python3}/bin/python"] else ["NO_PYTHON=1"])
 122   ++ lib.optionals stdenv.hostPlatform.isSunOS ["INSTALL=install" "NO_INET_NTOP=" "NO_INET_PTON="]
 123   ++ (if stdenv.hostPlatform.isDarwin then ["NO_APPLE_COMMON_CRYPTO=1"] else ["sysconfdir=/etc"])
 124   ++ lib.optionals stdenv.hostPlatform.isMusl ["NO_SYS_POLL_H=1" "NO_GETTEXT=YesPlease"]
 125   ++ lib.optional withpcre2 "USE_LIBPCRE2=1"
 126   ++ lib.optional (!nlsSupport) "NO_GETTEXT=1"
 127   # git-gui refuses to start with the version of tk distributed with
 128   # macOS Catalina. We can prevent git from building the .app bundle
 129   # by specifying an invalid tk framework. The postInstall step will
 130   # then ensure that git-gui uses tcl/tk from nixpkgs, which is an
 131   # acceptable version.
 132   #
 133   # See https://github.com/Homebrew/homebrew-core/commit/dfa3ccf1e7d3901e371b5140b935839ba9d8b706
 134   ++ lib.optional stdenv.hostPlatform.isDarwin "TKFRAMEWORK=/nonexistent";
 135
 136   disallowedReferences = lib.optionals (stdenv.buildPlatform != stdenv.hostPlatform) [
 137     stdenv.shellPackage
 138   ];
 139
 140
 141   postBuild = ''
 142     make -C contrib/subtree
 143   '' + (lib.optionalString perlSupport ''
 144     make -C contrib/diff-highlight
 145   '') + (lib.optionalString osxkeychainSupport ''
 146     make -C contrib/credential/osxkeychain
 147   '') + (lib.optionalString withLibsecret ''
 148     make -C contrib/credential/libsecret
 149   '');
 150
 151
 152   ## Install
 153
 154   # WARNING: Do not `rm` or `mv` files from the source tree; use `cp` instead.
 155   #          We need many of these files during the installCheckPhase.
 156
 157   installFlags = [ "NO_INSTALL_HARDLINKS=1" ];
 158
 159   preInstall = (lib.optionalString osxkeychainSupport ''
 160     mkdir -p $out/bin
 161     ln -s $out/share/git/contrib/credential/osxkeychain/git-credential-osxkeychain $out/bin/
 162     rm -f $PWD/contrib/credential/osxkeychain/git-credential-osxkeychain.o
 163   '') + (lib.optionalString withLibsecret ''
 164     mkdir -p $out/bin
 165     ln -s $out/share/git/contrib/credential/libsecret/git-credential-libsecret $out/bin/
 166     rm -f $PWD/contrib/credential/libsecret/git-credential-libsecret.o
 167   '');
 168
 169   postInstall =
 170     ''
 171       notSupported() {
 172         unlink $1 || true
 173       }
 174
 175       # Install git-subtree.
 176       make -C contrib/subtree install ${lib.optionalString withManual "install-doc"}
 177       rm -rf contrib/subtree
 178
 179       # Install contrib stuff.
 180       mkdir -p $out/share/git
 181       cp -a contrib $out/share/git/
 182       mkdir -p $out/share/bash-completion/completions
 183       ln -s $out/share/git/contrib/completion/git-completion.bash $out/share/bash-completion/completions/git
 184       ln -s $out/share/git/contrib/completion/git-prompt.sh $out/share/bash-completion/completions/
 185       # only readme, developed in another repo
 186       rm -r contrib/hooks/multimail
 187       mkdir -p $out/share/git-core/contrib
 188       cp -a contrib/hooks/ $out/share/git-core/contrib/
 189       substituteInPlace $out/share/git-core/contrib/hooks/pre-auto-gc-battery \
 190         --replace ' grep' ' ${gnugrep}/bin/grep' \
 191
 192       # grep is a runtime dependency, need to patch so that it's found
 193       substituteInPlace $out/libexec/git-core/git-sh-setup \
 194           --replace ' grep' ' ${gnugrep}/bin/grep' \
 195           --replace ' egrep' ' ${gnugrep}/bin/egrep'
 196
 197       # Fix references to the perl, sed, awk and various coreutil binaries used by
 198       # shell scripts that git calls (e.g. filter-branch)
 199       SCRIPT="$(cat <<'EOS'
 200         BEGIN{
 201           @a=(
 202             '${gnugrep}/bin/grep', '${gnused}/bin/sed', '${gawk}/bin/awk',
 203             '${coreutils}/bin/cut', '${coreutils}/bin/basename', '${coreutils}/bin/dirname',
 204             '${coreutils}/bin/wc', '${coreutils}/bin/tr'
 205             ${lib.optionalString perlSupport ", '${perlPackages.perl}/bin/perl'"}
 206           );
 207         }
 208         foreach $c (@a) {
 209           $n=(split("/", $c))[-1];
 210           s|(?<=[^#][^/.-])\b''${n}(?=\s)|''${c}|g
 211         }
 212       EOS
 213       )"
 214       perl -0777 -i -pe "$SCRIPT" \
 215         $out/libexec/git-core/git-{sh-setup,filter-branch,merge-octopus,mergetool,quiltimport,request-pull,submodule,subtree,web--browse}
 216
 217
 218       # Also put git-http-backend into $PATH, so that we can use smart
 219       # HTTP(s) transports for pushing
 220       ln -s $out/libexec/git-core/git-http-backend $out/bin/git-http-backend
 221       ln -s $out/share/git/contrib/git-jump/git-jump $out/bin/git-jump
 222     '' + lib.optionalString perlSupport ''
 223       # wrap perl commands
 224       makeWrapper "$out/share/git/contrib/credential/netrc/git-credential-netrc.perl" $out/bin/git-credential-netrc \
 225                   --set PERL5LIB   "$out/${perlPackages.perl.libPrefix}:${perlPackages.makePerlPath perlLibs}"
 226       wrapProgram $out/libexec/git-core/git-cvsimport \
 227                   --set GITPERLLIB "$out/${perlPackages.perl.libPrefix}:${perlPackages.makePerlPath perlLibs}"
 228       wrapProgram $out/libexec/git-core/git-archimport \
 229                   --set GITPERLLIB "$out/${perlPackages.perl.libPrefix}:${perlPackages.makePerlPath perlLibs}"
 230       wrapProgram $out/libexec/git-core/git-instaweb \
 231                   --set GITPERLLIB "$out/${perlPackages.perl.libPrefix}:${perlPackages.makePerlPath perlLibs}"
 232       wrapProgram $out/libexec/git-core/git-cvsexportcommit \
 233                   --set GITPERLLIB "$out/${perlPackages.perl.libPrefix}:${perlPackages.makePerlPath perlLibs}"
 234
 235       # gzip (and optionally bzip2, xz, zip) are runtime dependencies for
 236       # gitweb.cgi, need to patch so that it's found
 237       sed -i -e "s|'compressor' => \['gzip'|'compressor' => ['${gzip}/bin/gzip'|" \
 238           $out/share/gitweb/gitweb.cgi
 239       # Give access to CGI.pm and friends (was removed from perl core in 5.22)
 240       for p in ${lib.concatStringsSep " " gitwebPerlLibs}; do
 241           sed -i -e "/use CGI /i use lib \"$p/${perlPackages.perl.libPrefix}\";" \
 242               "$out/share/gitweb/gitweb.cgi"
 243       done
 244     ''
 245
 246    + (if svnSupport then ''
 247         # wrap git-svn
 248         wrapProgram $out/libexec/git-core/git-svn \
 249           --set GITPERLLIB "$out/${perlPackages.perl.libPrefix}:${perlPackages.makePerlPath (perlLibs ++ [svn.out])}" \
 250           --prefix PATH : "${svn.out}/bin"
 251       '' else ''
 252         # replace git-svn by notification script
 253         notSupported $out/libexec/git-core/git-svn
 254      '')
 255
 256    + (if sendEmailSupport then ''
 257         # wrap git-send-email
 258         wrapProgram $out/libexec/git-core/git-send-email \
 259                      --set GITPERLLIB "$out/${perlPackages.perl.libPrefix}:${perlPackages.makePerlPath smtpPerlLibs}"
 260       '' else ''
 261         # replace git-send-email by notification script
 262         notSupported $out/libexec/git-core/git-send-email
 263       '')
 264
 265    + lib.optionalString withManual ''
 266        # Install man pages
 267        make -j $NIX_BUILD_CORES PERL_PATH="${buildPackages.perl}/bin/perl" cmd-list.made install install-html \
 268          -C Documentation
 269      ''
 270
 271    + (if guiSupport then ''
 272        # Wrap Tcl/Tk programs
 273        for prog in bin/gitk libexec/git-core/{git-gui,git-citool,git-gui--askpass}; do
 274          sed -i -e "s|exec 'wish'|exec '${tk}/bin/wish'|g" \
 275                 -e "s|exec wish|exec '${tk}/bin/wish'|g" \
 276                 "$out/$prog"
 277        done
 278        ln -s $out/share/git/contrib/completion/git-completion.bash $out/share/bash-completion/completions/gitk
 279      '' else ''
 280        # Don't wrap Tcl/Tk, replace them by notification scripts
 281        for prog in bin/gitk libexec/git-core/git-gui; do
 282          notSupported "$out/$prog"
 283        done
 284      '')
 285    + lib.optionalString osxkeychainSupport ''
 286     # enable git-credential-osxkeychain on darwin if desired (default)
 287     mkdir -p $out/etc
 288     cat > $out/etc/gitconfig << EOF
 289     [credential]
 290       helper = osxkeychain
 291     EOF
 292   '';
 293
 294
 295   ## InstallCheck
 296
 297   doCheck = false;
 298   inherit doInstallCheck;
 299
 300   installCheckTarget = "test";
 301
 302   # see also installCheckFlagsArray
 303   installCheckFlags = [
 304     "DEFAULT_TEST_TARGET=prove"
 305     "PERL_PATH=${buildPackages.perl}/bin/perl"
 306   ];
 307
 308   nativeInstallCheckInputs = lib.optional (stdenv.hostPlatform.isDarwin || stdenv.hostPlatform.isFreeBSD) sysctl;
 309
 310   preInstallCheck = ''
 311     installCheckFlagsArray+=(
 312       GIT_PROVE_OPTS="--jobs $NIX_BUILD_CORES --failures --state=failed,save"
 313       GIT_TEST_INSTALLED=$out/bin
 314       ${lib.optionalString (!svnSupport) "NO_SVN_TESTS=y"}
 315     )
 316
 317     function disable_test {
 318       local test=$1 pattern=$2
 319       if [ $# -eq 1 ]; then
 320         mv t/{,skip-}$test.sh || true
 321       else
 322         sed -i t/$test.sh \
 323           -e "/^\s*test_expect_.*$pattern/,/^\s*' *\$/{s/^/: #/}"
 324       fi
 325     }
 326
 327     # Shared permissions are forbidden in sandbox builds:
 328     substituteInPlace t/test-lib.sh \
 329       --replace "test_set_prereq POSIXPERM" ""
 330     # TODO: Investigate while these still fail (without POSIXPERM):
 331     # Tested to fail: 2.46.0
 332     disable_test t0001-init 'shared overrides system'
 333     # Tested to fail: 2.46.0
 334     disable_test t0001-init 'init honors global core.sharedRepository'
 335     # Tested to fail: 2.46.0
 336     disable_test t1301-shared-repo
 337     # /build/git-2.44.0/contrib/completion/git-completion.bash: line 452: compgen: command not found
 338     disable_test t9902-completion
 339
 340     # Our patched gettext never fallbacks
 341     disable_test t0201-gettext-fallbacks
 342   '' + lib.optionalString (!sendEmailSupport) ''
 343     # Disable sendmail tests
 344     disable_test t9001-send-email
 345   '' + ''
 346     # Flaky tests:
 347     disable_test t6421-merge-partial-clone
 348
 349     # Fails reproducibly on ZFS on Linux with formD normalization
 350     disable_test t0021-conversion
 351     disable_test t3910-mac-os-precompose
 352   '' + lib.optionalString stdenv.hostPlatform.isDarwin ''
 353     # XXX: Some tests added in 2.24.0 fail.
 354     # Please try to re-enable on the next release.
 355     disable_test t7816-grep-binary-pattern
 356     # fail (as of 2.33.0)
 357     #===(   18623;1208  8/?  224/?  2/? )= =fatal: Not a valid object name refs/tags/signed-empty
 358     disable_test t6300-for-each-ref
 359     # not ok 1 - populate workdir (with 2.33.1 on x86_64-darwin)
 360     disable_test t5003-archive-zip
 361   '' + lib.optionalString (stdenv.hostPlatform.isDarwin && stdenv.hostPlatform.isAarch64) ''
 362     disable_test t7527-builtin-fsmonitor
 363   '' + lib.optionalString stdenv.hostPlatform.isMusl ''
 364     # Test fails (as of 2.17.0, musl 1.1.19)
 365     disable_test t3900-i18n-commit
 366     # Fails largely due to assumptions about BOM
 367     # Tested to fail: 2.18.0
 368     disable_test t0028-working-tree-encoding
 369   '';
 370
 371   stripDebugList = [ "lib" "libexec" "bin" "share/git/contrib/credential/libsecret" ];
 372
 373   passthru = {
 374     shellPath = "/bin/git-shell";
 375     tests = {
 376       withInstallCheck = finalAttrs.finalPackage.overrideAttrs (_: {
 377         doInstallCheck = true;
 378       });
 379       buildbot-integration = nixosTests.buildbot;
 380     } // tests.fetchgit;
 381     updateScript = ./update.sh;
 382   };
 383
 384   meta = {
 385     homepage = "https://git-scm.com/";
 386     description = "Distributed version control system";
 387     license = lib.licenses.gpl2;
 388     changelog = "https://github.com/git/git/blob/v${version}/Documentation/RelNotes/${version}.txt";
 389
 390     longDescription = ''
 391       Git, a popular distributed version control system designed to
 392       handle very large projects with speed and efficiency.
 393     '';
 394
 395     platforms = lib.platforms.all;
 396     maintainers = with lib.maintainers; [ primeos wmertens globin kashw2 ];
 397     mainProgram = "git";
 398   };
 399 })