pkgs/applications/video/mpv/scripts/webtorrent-mpv-hook.nix

   1 {
   2   lib,
   3   buildNpmPackage,
   4   fetchFromGitHub,
   5   gitUpdater,
   6   nodejs,
   7   python3,
   8 }:
   9
  10 buildNpmPackage rec {
  11   pname = "webtorrent-mpv-hook";
  12   version = "1.4.1";
  13
  14   src = fetchFromGitHub {
  15     owner = "mrxdst";
  16     repo = pname;
  17     rev = "v${version}";
  18     hash = "sha256-/dMtXcIyfAs++Zgz2CxRW0tkzn5QjS+WVGChlCyrU0U=";
  19   };
  20   passthru.updateScript = gitUpdater { rev-prefix = "v"; };
  21
  22   postPatch = ''
  23     substituteInPlace src/webtorrent.ts --replace-fail "node_path: 'node'" "node_path: '${lib.getExe nodejs}'"
  24     # This executable is just for telling non-Nix users how to install
  25     substituteInPlace package.json --replace-fail '"bin": "build/bin.mjs",' ""
  26     rm -rf src/bin.ts
  27   '';
  28
  29   npmDepsHash = "sha256-EqHPBoYyBuW9elxQH/XVTZoPkKHC6+7aksYo60t7WA4=";
  30   makeCacheWritable = true;
  31
  32   nativeBuildInputs = [
  33     python3 # Fixes node-gyp on aarch64-linux
  34   ];
  35
  36   postInstall = ''
  37     mkdir -p $out/share/mpv/scripts/
  38     ln -s $out/lib/node_modules/webtorrent-mpv-hook/build/webtorrent.js $out/share/mpv/scripts/
  39   '';
  40   passthru.scriptName = "webtorrent.js";
  41
  42   meta = {
  43     description = "Adds a hook that allows mpv to stream torrents";
  44     homepage = "https://github.com/mrxdst/webtorrent-mpv-hook";
  45     maintainers = [ lib.maintainers.chuangzhu ];
  46     license = lib.licenses.isc;
  47   };
  48 }