pkgs/applications/window-managers/dwm/dwm-status.nix

   1 {
   2   lib,
   3   rustPlatform,
   4   fetchFromGitHub,
   5   dbus,
   6   gdk-pixbuf,
   7   libnotify,
   8   makeWrapper,
   9   pkg-config,
  10   xorg,
  11   enableAlsaUtils ? true,
  12   alsa-utils,
  13   coreutils,
  14   enableNetwork ? true,
  15   dnsutils,
  16   iproute2,
  17   wirelesstools,
  18 }:
  19
  20 let
  21   bins =
  22     lib.optionals enableAlsaUtils [
  23       alsa-utils
  24       coreutils
  25     ]
  26     ++ lib.optionals enableNetwork [
  27       dnsutils
  28       iproute2
  29       wirelesstools
  30     ];
  31 in
  32
  33 rustPlatform.buildRustPackage rec {
  34   pname = "dwm-status";
  35   version = "1.9.0";
  36
  37   src = fetchFromGitHub {
  38     owner = "Gerschtli";
  39     repo = pname;
  40     rev = version;
  41     sha256 = "sha256-OFwI4evwbXLO4ufjrh5SZia79bwbAKVoSm/IPCDku68=";
  42   };
  43
  44   nativeBuildInputs = [
  45     makeWrapper
  46     pkg-config
  47   ];
  48   buildInputs = [
  49     dbus
  50     gdk-pixbuf
  51     libnotify
  52     xorg.libX11
  53   ];
  54
  55   cargoHash = "sha256-CNhRMJZJMMKh5L308a93YL0kJLkt6DdlmILMVPQV90Q=";
  56
  57   postInstall = lib.optionalString (bins != [ ]) ''
  58     wrapProgram $out/bin/dwm-status --prefix "PATH" : "${lib.makeBinPath bins}"
  59   '';
  60
  61   meta = with lib; {
  62     description = "Highly performant and configurable DWM status service";
  63     homepage = "https://github.com/Gerschtli/dwm-status";
  64     changelog = "https://github.com/Gerschtli/dwm-status/blob/master/CHANGELOG.md";
  65     license = with licenses; [ mit ];
  66     maintainers = with maintainers; [ gerschtli ];
  67     mainProgram = "dwm-status";
  68     platforms = platforms.linux;
  69   };
  70 }