pkgs/by-name/al/alpaca/package.nix

   1 {
   2   lib,
   3   python3Packages,
   4   fetchFromGitHub,
   5   appstream,
   6   meson,
   7   ninja,
   8   pkg-config,
   9   gobject-introspection,
  10   wrapGAppsHook4,
  11   desktop-file-utils,
  12   libadwaita,
  13   gtksourceview5,
  14   xdg-utils,
  15   ollama,
  16   vte-gtk4,
  17 }:
  18
  19 python3Packages.buildPythonApplication rec {
  20   pname = "alpaca";
  21   version = "2.9.0";
  22   pyproject = false; # Built with meson
  23
  24   src = fetchFromGitHub {
  25     owner = "Jeffser";
  26     repo = "Alpaca";
  27     rev = "refs/tags/${version}";
  28     hash = "sha256-ionioPA69haDIyXjqU84nuTNtI32jOnhd6oCTRI6vcA=";
  29   };
  30
  31   nativeBuildInputs = [
  32     appstream
  33     meson
  34     ninja
  35     pkg-config
  36     gobject-introspection
  37     wrapGAppsHook4
  38     desktop-file-utils
  39   ];
  40
  41   buildInputs = [
  42     libadwaita
  43     gtksourceview5
  44     vte-gtk4
  45   ];
  46
  47   dependencies = with python3Packages; [
  48     pygobject3
  49     requests
  50     pillow
  51     pypdf
  52     pytube
  53     html2text
  54     youtube-transcript-api
  55     pydbus
  56   ];
  57
  58   dontWrapGApps = true;
  59
  60   makeWrapperArgs = [
  61     "\${gappsWrapperArgs[@]}"
  62     "--prefix PATH : ${lib.makeBinPath [ xdg-utils ollama ]}"
  63     # Declared but not used in src/window.py, for later reference
  64     # https://github.com/flatpak/flatpak/issues/3229
  65     "--set FLATPAK_DEST ${placeholder "out"}"
  66   ];
  67
  68   meta = {
  69     description = "Ollama client made with GTK4 and Adwaita";
  70     longDescription = ''
  71       To run Alpaca with GPU acceleration enabled, simply override it:
  72       ```nix
  73       pkgs.alpaca.override {
  74         ollama = pkgs.ollama-cuda;
  75       }
  76       ```
  77       Or using `pkgs.ollama-rocm` for AMD GPUs.
  78     '';
  79     homepage = "https://jeffser.com/alpaca";
  80     license = lib.licenses.gpl3Plus;
  81     mainProgram = "alpaca";
  82     maintainers = with lib.maintainers; [ aleksana ];
  83     platforms = lib.platforms.linux;
  84   };
  85 }