pkgs/by-name/al/alsa-tools/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchurl,
   5   alsa-lib,
   6   fltk13,
   7   gtk2,
   8   gtk3,
   9   makeWrapper,
  10   pkg-config,
  11   psmisc,
  12 }:
  13
  14 stdenv.mkDerivation (finalAttrs: {
  15   pname = "alsa-tools";
  16   version = "1.2.11";
  17
  18   src = fetchurl {
  19     url = "mirror://alsa/tools/alsa-tools-${finalAttrs.version}.tar.bz2";
  20     hash = "sha256-CRXJY0pQL9NlXKnFdNJZvJ55mD2R1Frqz/bzwA+K4+k=";
  21   };
  22
  23   nativeBuildInputs = [
  24     makeWrapper
  25     pkg-config
  26   ];
  27
  28   buildInputs = [
  29     alsa-lib
  30     fltk13
  31     gtk2
  32     gtk3
  33     psmisc
  34   ];
  35
  36   env.TOOLSET = lib.concatStringsSep " " [
  37     "as10k1"
  38     "echomixer"
  39     "envy24control"
  40     "hda-verb"
  41     "hdajackretask"
  42     "hdajacksensetest"
  43     "hdspconf"
  44     "hdsploader"
  45     "hdspmixer"
  46     # "hwmixvolume" # Requires old, unmaintained, abandoned EOL Python 2
  47     "ld10k1"
  48     # "qlo10k1" # needs Qt
  49     "mixartloader"
  50     "pcxhrloader"
  51     "rmedigicontrol"
  52     "sb16_csp"
  53     # "seq" # mysterious configure error
  54     "sscape_ctl"
  55     "us428control"
  56     # "usx2yloader" # tries to create /etc/hotplug/usb
  57     "vxloader"
  58   ];
  59
  60   configurePhase = ''
  61     runHook preConfigure
  62
  63     for tool in $TOOLSET; do
  64       echo "Configuring $tool:"
  65       pushd "$tool"
  66       ./configure --prefix="$out"
  67       popd
  68     done
  69
  70     runHook postConfigure
  71   '';
  72
  73   buildPhase = ''
  74     runHook preBuild
  75
  76     for tool in $TOOLSET; do
  77       echo "Building $tool:"
  78       pushd "$tool"
  79       make
  80       popd
  81     done
  82
  83     runHook postBuild
  84   '';
  85
  86   installPhase = ''
  87     runHook preInstall
  88
  89     for tool in $TOOLSET; do
  90       echo "Installing $tool:"
  91       pushd "$tool"
  92       make install
  93       popd
  94     done
  95
  96     runHook postInstall
  97   '';
  98
  99   fixupPhase = ''
 100     runHook preFixup
 101
 102     wrapProgram $out/bin/hdajackretask \
 103       --prefix PATH : ${lib.makeBinPath [ psmisc ]}
 104
 105     runHook postFixup
 106   '';
 107
 108   meta = {
 109     homepage = "http://www.alsa-project.org/";
 110     description = "ALSA Tools";
 111     license = lib.licenses.gpl2Plus;
 112     maintainers = [ ];
 113     platforms = lib.platforms.linux;
 114   };
 115 })