pkgs/by-name/al/alsa-utils/package.nix

   1 { lib
   2 , stdenv
   3 , directoryListingUpdater
   4 , fetchurl
   5 , alsa-lib
   6 , alsa-plugins
   7 , gettext
   8 , makeWrapper
   9 , ncurses
  10 , libsamplerate
  11 , pciutils
  12 , procps
  13 , which
  14 , fftw
  15 , pipewire
  16 , withPipewireLib ? true
  17 , symlinkJoin
  18 }:
  19
  20 let
  21   plugin-packages = [ alsa-plugins ] ++ lib.optional withPipewireLib pipewire;
  22
  23   # Create a directory containing symlinks of all ALSA plugins.
  24   # This is necessary because ALSA_PLUGIN_DIR must reference only one directory.
  25   plugin-dir = symlinkJoin {
  26     name = "all-plugins";
  27     paths = map
  28       (path: "${path}/lib/alsa-lib")
  29       plugin-packages;
  30   };
  31 in
  32 stdenv.mkDerivation rec {
  33   pname = "alsa-utils";
  34   version = "1.2.12";
  35
  36   src = fetchurl {
  37     url = "mirror://alsa/utils/alsa-utils-${version}.tar.bz2";
  38     hash = "sha256-mLxmd9DAB0AGZ5BRgiMkoKsIea6lWKj2i1EXgNMM2SQ=";
  39   };
  40
  41   nativeBuildInputs = [ gettext makeWrapper ];
  42   buildInputs = [ alsa-lib ncurses libsamplerate fftw ];
  43
  44   configureFlags = [ "--disable-xmlto" "--with-udev-rules-dir=$(out)/lib/udev/rules.d" ];
  45
  46   installFlags = [ "ASOUND_STATE_DIR=$(TMPDIR)/dummy" ];
  47
  48   postFixup = ''
  49     mv $out/bin/alsa-info.sh $out/bin/alsa-info
  50     wrapProgram $out/bin/alsa-info --prefix PATH : "${lib.makeBinPath [ which pciutils procps ]}"
  51     wrapProgram $out/bin/aplay --set-default ALSA_PLUGIN_DIR ${plugin-dir}
  52   '';
  53
  54   passthru.updateScript = directoryListingUpdater {
  55     url = "https://www.alsa-project.org/files/pub/utils/";
  56   };
  57
  58   meta = with lib; {
  59     homepage = "http://www.alsa-project.org/";
  60     description = "ALSA, the Advanced Linux Sound Architecture utils";
  61     longDescription = ''
  62       The Advanced Linux Sound Architecture (ALSA) provides audio and
  63       MIDI functionality to the Linux-based operating system.
  64     '';
  65
  66     license = licenses.gpl2;
  67     platforms = platforms.linux;
  68     maintainers = [ ];
  69   };
  70 }