pkgs/by-name/an/ani-cli/package.nix

   1 {
   2   fetchFromGitHub,
   3   makeWrapper,
   4   stdenvNoCC,
   5   lib,
   6   gnugrep,
   7   gnused,
   8   curl,
   9   catt,
  10   syncplay,
  11   ffmpeg,
  12   fzf,
  13   aria2,
  14   mpv,
  15   vlc,
  16   iina,
  17   withMpv ? true,
  18   withVlc ? false,
  19   withIina ? false,
  20   chromecastSupport ? false,
  21   syncSupport ? false,
  22 }:
  23
  24 let
  25   players = lib.optional withMpv mpv ++ lib.optional withVlc vlc ++ lib.optional withIina iina;
  26 in
  27
  28 stdenvNoCC.mkDerivation (finalAttrs: {
  29   pname = "ani-cli";
  30   version = "4.9";
  31
  32   src = fetchFromGitHub {
  33     owner = "pystardust";
  34     repo = "ani-cli";
  35     rev = "v${finalAttrs.version}";
  36     hash = "sha256-7zuepWTtrFp9RW3zTSjPzyJ9e+09PdKgwcnV+DqPEUY=";
  37   };
  38
  39   nativeBuildInputs = [ makeWrapper ];
  40   runtimeInputs = [
  41     gnugrep
  42     gnused
  43     curl
  44     fzf
  45     ffmpeg
  46     aria2
  47   ] ++ lib.optional chromecastSupport catt ++ lib.optional syncSupport syncplay;
  48
  49   installPhase = ''
  50     runHook preInstall
  51
  52     install -Dm755 ani-cli $out/bin/ani-cli
  53
  54     wrapProgram $out/bin/ani-cli \
  55       --prefix PATH : ${lib.makeBinPath finalAttrs.runtimeInputs} \
  56       ${lib.optionalString (builtins.length players > 0) "--suffix PATH : ${lib.makeBinPath players}"}
  57
  58     runHook postInstall
  59   '';
  60
  61   meta = {
  62     homepage = "https://github.com/pystardust/ani-cli";
  63     description = "Cli tool to browse and play anime";
  64     license = lib.licenses.gpl3Plus;
  65     maintainers = with lib.maintainers; [
  66       skykanin
  67       diniamo
  68     ];
  69     platforms = lib.platforms.unix;
  70     mainProgram = "ani-cli";
  71   };
  72 })