pkgs/by-name/ay/ayatana-webmail/package.nix

   1 {
   2   lib,
   3   fetchFromGitHub,
   4   gettext,
   5   gtk3,
   6   python3Packages,
   7   gdk-pixbuf,
   8   libnotify,
   9   glib,
  10   gobject-introspection,
  11   wrapGAppsHook3,
  12   # BTW libappindicator is also supported, but upstream recommends their
  13   # implementation, see:
  14   # https://github.com/AyatanaIndicators/ayatana-webmail/issues/24#issuecomment-1050352862
  15   libayatana-appindicator,
  16   gsettings-desktop-schemas,
  17   libcanberra-gtk3,
  18 }:
  19
  20 python3Packages.buildPythonApplication rec {
  21   pname = "ayatana-webmail";
  22   version = "24.5.17";
  23
  24   src = fetchFromGitHub {
  25     owner = "AyatanaIndicators";
  26     repo = "ayatana-webmail";
  27     rev = "refs/tags/${version}";
  28     hash = "sha256-k557FWKGq2MXODVxVzOetC5kkwTNYOoLO8msCOabais=";
  29   };
  30   postConfigure = ''
  31     # Fix fhs paths
  32     substituteInPlace \
  33       ayatanawebmail/accounts.py \
  34       ayatanawebmail/actions.py \
  35       ayatanawebmail/dialog.py \
  36       --replace-fail /usr/share $out/share
  37   '';
  38
  39   buildInputs = [
  40     gtk3
  41     gdk-pixbuf
  42     glib
  43     libnotify
  44     gettext
  45     libayatana-appindicator
  46     gsettings-desktop-schemas
  47   ];
  48
  49   nativeBuildInputs = [
  50     gobject-introspection
  51     wrapGAppsHook3
  52     glib # For compiling gsettings-schemas
  53   ];
  54
  55   propagatedBuildInputs = with python3Packages; [
  56     urllib3
  57     babel
  58     psutil
  59     secretstorage
  60     polib
  61     pygobject3
  62     dbus-python
  63   ];
  64
  65   # No tests, and they cause a failure
  66   doCheck = false;
  67
  68   postInstall = ''
  69     # Fix fhs paths
  70     mv $out/${python3Packages.python.sitePackages}/etc $out
  71     mv $out/${python3Packages.python.sitePackages}/usr/{bin,share} $out/
  72     rmdir $out/${python3Packages.python.sitePackages}/usr
  73     # Compile gsettings desktop schemas
  74     glib-compile-schemas $out/share/glib-2.0/schemas
  75   '';
  76
  77   # See https://nixos.org/nixpkgs/manual/#ssec-gnome-common-issues-double-wrapped
  78   dontWrapGApps = true;
  79   preFixup = ''
  80     makeWrapperArgs+=("''${gappsWrapperArgs[@]}")
  81     makeWrapperArgs+=(--prefix PATH : ${lib.makeBinPath [ libcanberra-gtk3 ]})
  82   '';
  83
  84   meta = {
  85     description = "Webmail notifications and actions for any desktop";
  86     homepage = "https://github.com/AyatanaIndicators/ayatana-webmail";
  87     license = lib.licenses.gpl3Plus;
  88     platforms = lib.platforms.linux;
  89     maintainers = with lib.maintainers; [ doronbehar ];
  90   };
  91 }