pkgs/by-name/bs/bsd-finger/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchurl,
   5   fetchpatch,
   6   # Configurable options
   7   buildProduct ? # can be "client" or "daemon"
   8     if buildClient != null then
   9       lib.warn ''
  10         buildClient is deprecated;
  11         use buildProduct instead
  12       '' (if buildClient then "client" else "daemon")
  13     else
  14       "client",
  15   # Deprecated options
  16   # Remove them before next version of either Nixpkgs or bsd-finger itself
  17   buildClient ? null,
  18 }:
  19
  20 assert lib.elem buildProduct [
  21   "client"
  22   "daemon"
  23 ];
  24 stdenv.mkDerivation (finalAttrs: {
  25   pname = "bsd-finger" + lib.optionalString (buildProduct == "daemon") "d";
  26   version = "0.17";
  27
  28   src = fetchurl {
  29     url = "http://ftp.de.debian.org/debian/pool/main/b/bsd-finger/bsd-finger_${finalAttrs.version}.orig.tar.bz2";
  30     hash = "sha256-KLNNYF0j6mh9eeD8SMA1q+gPiNnBVH56pGeW0QgcA2M=";
  31   };
  32
  33   patches =
  34     let
  35       debianRevision = "17";
  36       generateUrl =
  37         patchName:
  38         "https://sources.debian.org/data/main/b/bsd-finger/${finalAttrs.version}-${debianRevision}/debian/patches/${patchName}.patch";
  39     in
  40     [
  41       # Patches original finger sources to make the programs more robust and
  42       # compatible
  43       (fetchpatch {
  44         url = generateUrl "01-legacy";
  45         hash = "sha256-84znJLXez4w6WB2nOW+PHK/0srE0iG9nGAjO1/AGczw=";
  46       })
  47
  48       # http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=518559
  49       #
  50       # Doesn't work with a non-iterable nsswitch source
  51       #
  52       # Currently, "finger tabbott" works by iterating through the list of users
  53       # on the system using getpwent and checking if any of them match
  54       # "tabbott".
  55       #
  56       # Some nsswitch backends (including Hesiod and LDAP[1]) do not support
  57       # iterating through the complete list of users.  These nsswitch backends
  58       # instead only fully support looking up a user's information by username
  59       # or uid.
  60       #
  61       # So, if tabbott is a user whose nsswitch information comes from LDAP,
  62       # then "finger tabbott" will incorrectly report "finger: tabbott: no such
  63       # user."  "finger -m tabbott" does work correctly, however, because it
  64       # looks up the matching username using getpwnam.
  65       #
  66       # A fix for this is to always look up an argument to finger for a username
  67       # match, and having -m only control whether finger searches the entire
  68       # user database for real name matches.  Patch attached.
  69       #
  70       # This patch has the advantageous side effect that if there are some real
  71       # name matches and a username match, finger will always display the
  72       # username match first (rather than in some random place in the list).
  73       #
  74       #     -Tim Abbott
  75       #
  76       # [1] with LDAP, it is typically the case that one can iterate through
  77       # only the first 100 results from a query.
  78       (fetchpatch {
  79         url = generateUrl "02-518559-nsswitch-sources";
  80         hash = "sha256-oBXJ/kr/czevWk0TcsutGINNwCoHnEStRT8Jfgp/lbM=";
  81       })
  82
  83       # http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=468454
  84       # Implement IPv6 capacity for the server Fingerd.
  85       (fetchpatch {
  86         url = generateUrl "03-468454-fingerd-ipv6";
  87         hash = "sha256-a5+qoy2UKa2nCJrwrfJ5VPZoACFXFQ1j/rweoMYW1Z0=";
  88       })
  89
  90       # http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=468454
  91       # Implement IPv6 capability for the client Finger.
  92       (fetchpatch {
  93         url = generateUrl "04-468454-finger-ipv6";
  94         hash = "sha256-cg93NL02lJm/5Freegb3EbjDAQVkurLEEJifcyQRRfk=";
  95       })
  96
  97       # http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=547014
  98       # From: "Matthew A. Dunford" <mdunford@lbl.gov>
  99       #
 100       # finger segfaults when it comes across a netgroup entry in /etc/passwd.
 101       # A netgroup entry doesn't include many of the fields in a normal passwd
 102       # entry, so pw->pw_gecos is set to NULL, which causes finger to core dump.
 103       #
 104       # Here is part of a /etc/passwd file with a netgroup entry:
 105       #
 106       # nobody:x:65534:65534:nobody:/nonexistent:/bin/sh +@operator
 107       #
 108       # This patch sidesteps what finger considers a malformed passwd entry:
 109       (fetchpatch {
 110         url = generateUrl "05-547014-netgroup";
 111         hash = "sha256-d+ufp7nPZwW+t+EWASzHrXT/O6zSzt6OOV12cKVo3P0=";
 112       })
 113
 114       # Decrease timeout length during connect().
 115       # In cases where a name server is answering with A as well as AAAA
 116       # records, but the system to be queried has lost a corresponding address,
 117       # the TCP handshake timeout will cause a long delay before allowing the
 118       # query of the next address family, or the next address in general.
 119       #  .
 120       # The use of a trivial signal handler for SIGALRM allows the reduction of
 121       # this timeout, thus producing better responsiveness for the interactive
 122       # user of the Finger service.
 123       # Author: Mats Erik Andersson <debian@gisladisker.se>
 124       (fetchpatch {
 125         url = generateUrl "06-572211-decrease-timeout";
 126         hash = "sha256-KtNGU5mmX1nnxQc7XnYoUuVW4We2cF81+x6EQrHF7g0=";
 127       })
 128
 129       # Use cmake as build system
 130       (fetchpatch {
 131         url = generateUrl "use-cmake-as-buildsystem";
 132         hash = "sha256-YOmkF6Oxowy15mCE1pCvHKnLEXglijWFG6eydnZJFhM=";
 133       })
 134
 135       # Debian-specific changes to the cmake build system (that NixOS will also
 136       # benefit from)
 137       # Adds -D_GNU_SOURCE, which will enable many C extensions that finger
 138       # benefits from
 139       (fetchpatch {
 140         url = generateUrl "use-cmake-as-buildsystem-debian-extras";
 141         hash = "sha256-T3DWpyyz15JCiVJ41RrJEhsmicei8G3OaKpxvzOCcBU=";
 142       })
 143
 144       # Fix typo at fingerd man page (Josue Ortega <josue@debian.org>)
 145       (fetchpatch {
 146         url = generateUrl "fix-fingerd-man-typo";
 147         hash = "sha256-f59osGi0a8Tkm2Vxg2+H2brH8WproCDvbPf4jXwi6ag=";
 148       })
 149     ];
 150
 151   env.NIX_CFLAGS_COMPILE = "-D_GNU_SOURCE";
 152
 153   preBuild =
 154     let
 155       subdir =
 156         {
 157           "client" = "finger";
 158           "daemon" = "fingerd";
 159         }
 160         .${buildProduct};
 161     in
 162     ''
 163       cd ${subdir}
 164     '';
 165
 166   preInstall =
 167     let
 168       bindir =
 169         {
 170           "client" = "bin";
 171           "daemon" = "sbin";
 172         }
 173         .${buildProduct};
 174
 175       mandir =
 176         {
 177           "client" = "man1";
 178           "daemon" = "man8";
 179         }
 180         .${buildProduct};
 181     in
 182     ''
 183       mkdir -p $out/${bindir} $out/man/${mandir}
 184     '';
 185
 186   postInstall = lib.optionalString (buildProduct == "daemon") ''
 187     pushd $out/sbin
 188     ln -s in.fingerd fingerd
 189     popd
 190   '';
 191
 192   meta = {
 193     description =
 194       {
 195         "client" = "User information lookup program";
 196         "daemon" = "Remote user information server";
 197       }
 198       .${buildProduct};
 199     license = lib.licenses.bsdOriginal;
 200     mainProgram =
 201       {
 202         "client" = "finger";
 203         "daemon" = "fingerd";
 204       }
 205       .${buildProduct};
 206     maintainers = with lib.maintainers; [ AndersonTorres ];
 207     platforms = lib.platforms.linux;
 208   };
 209 })