pkgs/by-name/bu/bulloak/package.nix

   1 {
   2   lib,
   3   fetchFromGitHub,
   4   rustPlatform,
   5   fetchurl,
   6   stdenv,
   7 }:
   8
   9 let
  10   # svm-rs-builds requires a list of solc versions to build, and would make network calls if not provided.
  11   # The ethereum project does not provide static binaries for aarch64, so we use separate sources, the same as in
  12   # svm-rs's source code.
  13   solc-versions = {
  14     x86_64-linux = fetchurl {
  15       url = "https://raw.githubusercontent.com/ethereum/solc-bin/60de887187e5670c715931a82fdff6677b31f0cb/linux-amd64/list.json";
  16       hash = "sha256-zm1cdqSP4Y9UQcq9OV8sXxnzr3+TWdc7mdg+Do8Y7WY=";
  17     };
  18     x86_64-darwin = fetchurl {
  19       url = "https://raw.githubusercontent.com/ethereum/solc-bin/60de887187e5670c715931a82fdff6677b31f0cb/macosx-amd64/list.json";
  20       hash = "sha256-uUdd5gCG7SHQgAW2DQXemTujb8bUJM27J02WjLkQgek=";
  21     };
  22     aarch64-linux = fetchurl {
  23       url = "https://raw.githubusercontent.com/nikitastupin/solc/923ab4b852fadc00ffe87bb76fff21d0613bd280/linux/aarch64/list.json";
  24       hash = "sha256-mJaEN63mR3XdK2FmEF+VhLR6JaCCtYkIRq00wYH6Xx8=";
  25     };
  26     aarch64-darwin = fetchurl {
  27       url = "https://raw.githubusercontent.com/alloy-rs/solc-builds/260964c1fcae2502c0139070bdc5c83eb7036a68/macosx/aarch64/list.json";
  28       hash = "sha256-xrtb3deMDAuDIjzN1pxm5NyW5NW5OyoOHTFsYyWJCYY=";
  29     };
  30   };
  31 in
  32 rustPlatform.buildRustPackage rec {
  33   pname = "bulloak";
  34   version = "0.8.0";
  35
  36   src = fetchFromGitHub {
  37     owner = "alexfertel";
  38     repo = "bulloak";
  39     rev = "v${version}";
  40     hash = "sha256-OAjy8SXaD+2/C5jLNIezv/KdrPHlwJC5L1LwGhqBWQs=";
  41   };
  42
  43   useFetchCargoVendor = true;
  44   cargoHash = "sha256-sdnpnKWKCJeBbooM0Qe/wccF1b3LLiTfZe4RdxbJYcs=";
  45
  46   # tests run in CI on the source repo
  47   doCheck = false;
  48
  49   # provide the list of solc versions to the `svm-rs-builds` dependency
  50   SVM_RELEASES_LIST_JSON = solc-versions.${stdenv.hostPlatform.system};
  51
  52   meta = {
  53     description = "Solidity test generator based on the Branching Tree Technique";
  54     homepage = "https://github.com/alexfertel/bulloak";
  55     license = with lib.licenses; [
  56       mit
  57       asl20
  58     ];
  59     mainProgram = "bulloak";
  60     maintainers = with lib.maintainers; [ beeb ];
  61   };
  62 }