pkgs/by-name/bu/bustle/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitLab,
   5   buildPackages,
   6   cargo,
   7   meson,
   8   ninja,
   9   pkg-config,
  10   desktop-file-utils,
  11   rustPlatform,
  12   rustc,
  13   wrapGAppsHook4,
  14   darwin,
  15   gettext,
  16   glib,
  17   gtk4,
  18   libadwaita,
  19   libiconv,
  20 }:
  21
  22 stdenv.mkDerivation (finalAttrs: {
  23   pname = "bustle";
  24   version = "0.10.0";
  25
  26   src = fetchFromGitLab {
  27     domain = "gitlab.gnome.org";
  28     owner = "World";
  29     repo = "bustle";
  30     rev = finalAttrs.version;
  31     hash = "sha256-5ZZiRD64OOMtTNxI0uvilGM22rsJv7vU3yPDY8ROrxU=";
  32   };
  33
  34   cargoDeps = rustPlatform.fetchCargoTarball {
  35     inherit (finalAttrs) pname version src;
  36     hash = "sha256-tUSGldWeCLEHi35bDLMnfjnfofF2Qse5uBu2mDGJrsE=";
  37   };
  38
  39   env = lib.optionalAttrs stdenv.hostPlatform.isDarwin {
  40     # Set the location to gettext to ensure the nixpkgs one on Darwin instead of the vendored one.
  41     # The vendored gettext does not build with clang 16.
  42     GETTEXT_BIN_DIR = "${lib.getBin buildPackages.gettext}/bin";
  43     GETTEXT_INCLUDE_DIR = "${lib.getDev gettext}/include";
  44     GETTEXT_LIB_DIR = "${lib.getLib gettext}/lib";
  45   };
  46
  47   nativeBuildInputs = [
  48     cargo
  49     meson
  50     ninja
  51     pkg-config
  52     desktop-file-utils
  53     rustPlatform.cargoSetupHook
  54     rustc
  55     wrapGAppsHook4
  56     glib
  57   ];
  58
  59   buildInputs = [
  60     glib
  61     gtk4
  62     libadwaita
  63   ];
  64
  65   meta = {
  66     description = "Graphical D-Bus message analyser and profiler";
  67     homepage = "https://gitlab.gnome.org/World/bustle";
  68     license = lib.licenses.lgpl21Plus;
  69     maintainers = with lib.maintainers; [
  70       jtojnar
  71       aleksana
  72     ];
  73     mainProgram = "bustle";
  74     platforms = lib.platforms.all;
  75   };
  76 })