pkgs/by-name/ca/cantarell-fonts/package.nix

   1 {
   2   stdenv,
   3   lib,
   4   fetchurl,
   5   meson,
   6   ninja,
   7   python3,
   8   gettext,
   9   appstream-glib,
  10   gnome,
  11 }:
  12
  13 stdenv.mkDerivation rec {
  14   pname = "cantarell-fonts";
  15   version = "0.303.1";
  16
  17   src = fetchurl {
  18     url = "mirror://gnome/sources/${pname}/${lib.versions.majorMinor version}/${pname}-${version}.tar.xz";
  19     sha256 = "+UY6BlnGPlfjgf3XU88ZKSJTlcW0kTWYlCR2GDBTBBE=";
  20   };
  21
  22   nativeBuildInputs = [
  23     meson
  24     ninja
  25     python3
  26     python3.pkgs.psautohint
  27     python3.pkgs.cffsubr
  28     python3.pkgs.statmake
  29     python3.pkgs.ufo2ft
  30     python3.pkgs.setuptools
  31     python3.pkgs.ufolib2
  32     gettext
  33     appstream-glib
  34   ];
  35
  36   # ad-hoc fix for https://github.com/NixOS/nixpkgs/issues/50855
  37   # until we fix gettext's envHook
  38   preBuild = ''
  39     export GETTEXTDATADIRS="$GETTEXTDATADIRS_FOR_BUILD"
  40   '';
  41
  42   outputHashAlgo = "sha256";
  43   outputHashMode = "recursive";
  44   outputHash = "XeqHVdTQ7PTzxkjwfzS/BTR7+k/M69sfUKdRXGOTmZE=";
  45
  46   passthru = {
  47     updateScript = gnome.updateScript {
  48       packageName = pname;
  49     };
  50   };
  51
  52   meta = {
  53     description = "Default typeface used in the user interface of GNOME since version 3.0";
  54     platforms = lib.platforms.all;
  55     license = lib.licenses.ofl;
  56     maintainers = [ ];
  57   };
  58 }