pkgs/by-name/ca/capitaine-cursors/package.nix

   1 {
   2   lib,
   3   stdenvNoCC,
   4   fetchFromGitHub,
   5   fetchpatch,
   6   makeFontsConf,
   7   inkscape,
   8   xcursorgen,
   9   bc,
  10 }:
  11
  12 stdenvNoCC.mkDerivation rec {
  13   pname = "capitaine-cursors";
  14   version = "4";
  15
  16   src = fetchFromGitHub {
  17     owner = "keeferrourke";
  18     repo = pname;
  19     rev = "r${version}";
  20     sha256 = "0652ydy73x29z7wc6ccyqihmfg4bk0ksl7yryycln6c7i0iqfmc9";
  21   };
  22
  23   patches = [
  24     # Fixes the build on inscape => 1.0, without this it generates empty cursor files
  25     (fetchpatch {
  26       name = "inkscape-1.0-compat";
  27       url = "https://github.com/keeferrourke/capitaine-cursors/commit/9da0b53e6098ed023c5c24c6ef6bfb1f68a79924.patch";
  28       sha256 = "0lx5i60ahy6a2pir4zzlqn5lqsv6claqg8mv17l1a028h9aha3cv";
  29     })
  30   ];
  31
  32   postPatch = ''
  33     patchShebangs .
  34   '';
  35
  36   # Complains about not being able to find the fontconfig config file otherwise
  37   FONTCONFIG_FILE = makeFontsConf { fontDirectories = [ ]; };
  38
  39   buildInputs = [
  40     inkscape
  41     xcursorgen
  42     bc
  43   ];
  44
  45   buildPhase = ''
  46     for variant in dark light ; do
  47     # https://github.com/NixOS/nixpkgs/blob/master/pkgs/data/fonts/emojione/default.nix#L16
  48       HOME="$NIX_BUILD_ROOT" ./build.sh --max-dpi xhd --type $variant
  49     done
  50   '';
  51
  52   installPhase = ''
  53     install -dm 0755 $out/share/icons
  54     cp -pr dist/dark $out/share/icons/capitaine-cursors
  55     cp -pr dist/light $out/share/icons/capitaine-cursors-white
  56   '';
  57
  58   meta = with lib; {
  59     description = "X-cursor theme inspired by macOS and based on KDE Breeze";
  60     homepage = "https://github.com/keeferrourke/capitaine-cursors";
  61     license = licenses.lgpl3;
  62     platforms = platforms.linux;
  63     maintainers = with maintainers; [ eadwu ];
  64   };
  65 }